File Coverage

blib/lib/App/MARC/List.pm

Criterion	Covered	Total	%
statement	93	93	100.0
branch	20	22	90.9
condition	15	15	100.0
subroutine	12	12	100.0
pod	2	2	100.0
total	142	144	98.6

package App::MARC::List;

use strict;
use warnings;

use Class::Utils qw(set_params);
use English;
use Error::Pure qw(err);
use Getopt::Std;
use List::MoreUtils qw(uniq);
use List::Util qw(max);
use MARC::File::XML (BinaryEncoding => 'utf8', RecordFormat => 'MARC21');
use Unicode::UTF8 qw(decode_utf8 encode_utf8);

our $VERSION = 0.07;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Process parameters.
	set_params($self, @params);

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'f' => 0,
		'h' => 0,
	};
	if (! getopts('fh', $self->{'_opts'})
		|| $self->{'_opts'}->{'h'}
		|| @ARGV < 2) {

		print STDERR "Usage: $0 [-f] [-h] [--version] marc_xml_file field [subfield]\n";
		print STDERR "\t-f\t\tPrint frequency.\n";
		print STDERR "\t-h\t\tPrint help.\n";
		print STDERR "\t--version\tPrint version.\n";
		print STDERR "\tmarc_xml_file\tMARC XML file.\n";
		print STDERR "\tfield\t\tMARC field (field number or 'leader' string).\n";
		print STDERR "\tsubfield\tMARC subfield (for datafields).\n";
		return 1;
	}
	$self->{'_marc_xml_file'} = shift @ARGV;
	$self->{'_marc_field'} = shift @ARGV;
	$self->{'_marc_subfield'} = shift @ARGV;

	if ($self->{'_marc_field'} ne 'leader'
		&& $self->{'_marc_field'} !~ m/^\d+$/ms) {

		err "Bad field definition. Must be a 'leader' or numeric value of the field.";
	}

	if ($self->{'_marc_field'} ne 'leader'
		&& int($self->{'_marc_field'}) > 9
		&& ! defined $self->{'_marc_subfield'}) {

		err 'Subfield is required.';
	}

	my $marc_file = MARC::File::XML->in($self->{'_marc_xml_file'});
	my $ret_hr = {};
	my $num = 1;
	my $previous_record;
	while (1) {
		my $record = eval {
			$marc_file->next;
		};
		if ($EVAL_ERROR) {
			print STDERR "Cannot process '$num' record. ".
				(
					defined $previous_record
					? "Previous record is ".encode_utf8($previous_record->title)."\n"
					: ''
				);
			print STDERR "Error: $EVAL_ERROR\n";
			next;
		}
		if (! defined $record) {
			last;
		}
		$previous_record = $record;

		if ($self->{'_marc_field'} eq 'leader') {
			my $leader = $record->leader;
			$ret_hr->{"'".$leader."'"}++;
		} else {
			my @fields = $record->field($self->{'_marc_field'});
			foreach my $field (@fields) {
				if (defined $self->{'_marc_subfield'}) {
					my @subfield_values = $field->subfield($self->{'_marc_subfield'});
					foreach my $subfield_value (@subfield_values) {
						$ret_hr->{$subfield_value}++;
					}
				} else {
					my $data = $field->data;
					$ret_hr->{$data}++;
				}
			}
		}
		$num++;
	}

	# Print out.
	if (%{$ret_hr}) {
		if ($self->{'_opts'}->{'f'}) {
			my $max = max(values %{$ret_hr});
			my $num = length($max);
			print join "\n",
				map { sprintf("%${num}s", $ret_hr->{$_}).' '.encode_utf8($_) }
				reverse sort {
					$ret_hr->{$a} <=> $ret_hr->{$b}
					||
					$a cmp $b
				}
				keys %{$ret_hr};
		} else {
			print join "\n", map { encode_utf8($_) } sort keys %{$ret_hr};
		}
		print "\n";
	}

	return 0;
}

1;


__END__