File Coverage

blib/lib/App/MARC/List.pm

Criterion	Covered	Total	%
statement	74	74	100.0
branch	12	14	85.7
condition	7	9	77.7
subroutine	11	11	100.0
pod	2	2	100.0
total	106	110	96.3

package App::MARC::List;

use strict;
use warnings;

use Class::Utils qw(set_params);
use English;
use Error::Pure qw(err);
use Getopt::Std;
use List::MoreUtils qw(uniq);
use MARC::File::XML (BinaryEncoding => 'utf8', RecordFormat => 'MARC21');
use Unicode::UTF8 qw(decode_utf8 encode_utf8);

our $VERSION = 0.02;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Process parameters.
	set_params($self, @params);

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'h' => 0,
	};
	if (! getopts('h', $self->{'_opts'}) || @ARGV < 1
		|| $self->{'_opts'}->{'h'}) {

		print STDERR "Usage: $0 [-h] [--version] marc_xml_file field subfield\n";
		print STDERR "\t-h\t\tPrint help.\n";
		print STDERR "\t--version\tPrint version.\n";
		print STDERR "\tmarc_xml_file\tMARC XML file.\n";
		print STDERR "\tfield\t\tMARC field.\n";
		print STDERR "\tsubfield\tMARC subfield.\n";
		return 1;
	}
	$self->{'_marc_xml_file'} = shift @ARGV;
	$self->{'_marc_field'} = shift @ARGV;
	$self->{'_marc_subfield'} = shift @ARGV;

	if (! defined $self->{'_marc_field'}
		|| ! defined $self->{'_marc_subfield'}) {

		err "Field and subfield is required.";
	}

	my $marc_file = MARC::File::XML->in($self->{'_marc_xml_file'});
	my $ret_hr = {};
	my $num = 1;
	my $previous_record;
	while (1) {
		my $record = eval {
			$marc_file->next;
		};
		if ($EVAL_ERROR) {
			print STDERR "Cannot process '$num' record. ".
				(
					defined $previous_record
					? "Previous record is ".encode_utf8($previous_record->title)."\n"
					: ''
				);
			print STDERR "Error: $EVAL_ERROR\n";
			next;
		}
		if (! defined $record) {
			last;
		}
		$previous_record = $record;

		my @fields = $record->field($self->{'_marc_field'});
		foreach my $field (@fields) {
			my @subfield_values = $field->subfield($self->{'_marc_subfield'});
			foreach my $subfield_value (@subfield_values) {
				if (! exists $ret_hr->{$subfield_value}) {
					$ret_hr->{$subfield_value} = $subfield_value;
				}
			}
		}
		$num++;
	}

	# Print out.
	if (%{$ret_hr}) {
		print join "\n", map { encode_utf8($_) } uniq sort keys %{$ret_hr};
		print "\n";
	}

	return 0;
}

1;


__END__