File Coverage

blib/lib/App/ISBN/Check.pm

Criterion	Covered	Total	%
statement	54	54	100.0
branch	12	12	100.0
condition	4	6	66.6
subroutine	9	9	100.0
pod	2	2	100.0
total	81	83	97.5

package App::ISBN::Check;

use strict;
use warnings;

use Business::ISBN;
use Class::Utils qw(set_params);
use Error::Pure qw(err);
use Getopt::Std;
use Perl6::Slurp qw(slurp);

our $VERSION = 0.01;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Process parameters.
	set_params($self, @params);

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'h' => 0,
	};
	if (! getopts('h', $self->{'_opts'}) || @ARGV < 1
		|| $self->{'_opts'}->{'h'}) {

		print STDERR "Usage: $0 [-h] [--version] file_with_isbns\n";
		print STDERR "\t-h\t\tPrint help.\n";
		print STDERR "\t--version\tPrint version.\n";
		print STDERR "\tfile_with_isbns\tFile with ISBN strings, one per line.\n";
		return 1;
	}
	$self->{'_file'} = shift @ARGV;

	my @isbns = slurp($self->{'_file'}, { chomp => 1 });

	foreach my $isbn (@isbns) {
		my $isbn_obj = Business::ISBN->new($isbn);
		if (! $isbn_obj) {
			print STDERR $isbn.": Cannot parse.\n";
			next;
		}
		if (! $isbn_obj->is_valid) {
			$isbn_obj->fix_checksum;
		}
		if (! $isbn_obj->is_valid) {
			print STDERR $isbn.": Not valid.\n";
			next;
		}

		my $isbn_concrete;
		my $isbn_without_dash = $isbn;
		$isbn_without_dash =~ s/-//msg;
		if (length $isbn_without_dash > 10) {
			$isbn_concrete = $isbn_obj->as_isbn13;
		} else {
			$isbn_concrete = $isbn_obj->as_isbn10;
		}
		if ($isbn ne $isbn_concrete->as_string) {
			print STDERR $isbn.": Different after format (".$isbn_concrete->as_string.").\n";
		}
	}

	return 0;
}

1;

__END__