File Coverage

blib/lib/App/HL7/Dump.pm

Criterion	Covered	Total	%
statement	24	60	40.0
branch	0	16	0.0
condition	0	6	0.0
subroutine	8	10	80.0
pod	2	2	100.0
total	34	94	36.1

package App::HL7::Dump;

use strict;
use warnings;

use Class::Utils qw(set_params);
use English;
use Error::Pure qw(err);
use Getopt::Std;
use Net::HL7::Message;
use Perl6::Slurp qw(slurp);

our $VERSION = 0.04;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Process params.
	set_params($self, @params);

	# Process arguments.
	$self->{'_opts'} = {
		'c' => 0,
		'h' => 0,
	};
	if (! getopts('ch', $self->{'_opts'}) || @ARGV < 1
		|| $self->{'_opts'}->{'h'}) {

		print STDERR "Usage: $0 [-c] [-h] [--version] hl7_file\n";
		print STDERR "\t-c\t\tColor mode.\n";
		print STDERR "\t-h\t\tHelp.\n";
		print STDERR "\t--version\tPrint version.\n";
		exit 1;
	}
	$self->{'_hl7_file'} = $ARGV[0];

	if ($ENV{'COLOR'}) {
		$self->{'_opts'}->{'c'} = 1;
	}

	# Load Term::ANSIColor.
	if ($self->{'_opts'}->{'c'}) {
		eval "require Term::ANSIColor;";
		if ($EVAL_ERROR) {
			err "Cannot load 'Term::ANSIColor'.",
				'Eval error', $EVAL_ERROR;
		}
	}

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Get hl7_file.
	my $hl7 = slurp($self->{'_hl7_file'});

	# Create message.
	my $msg = Net::HL7::Message->new($hl7);
	if (! $msg) {
		err 'Cannot parse HL7 file.', 'File', $self->{'_hl7_file'};
		return 1;
	}

	# Segment name: size
	foreach my $seg ($msg->getSegments) {
		foreach my $index (1 .. $seg->size) {
			my $val = $seg->getField($index);
			if (defined $val) {
				my $print_val;
				if (ref $val eq 'ARRAY') {
					$print_val = $seg->getFieldAsString($index);
				} else {
					$print_val = $val;
				}
				if ($self->{'_opts'}->{'c'}) {
					print Term::ANSIColor::color('green').$seg->getName.
						Term::ANSIColor::color('reset').'-'.
						Term::ANSIColor::color('red').$index.
						Term::ANSIColor::color('reset').':'.
						Term::ANSIColor::color('bold white').
						$print_val.Term::ANSIColor::color('reset')."\n";
				} else {
					print $seg->getName.'-'.$index.':'.$print_val."\n";
				}
			}
		}
	}

	return 0;
}

1;


__END__