File Coverage

blib/lib/App/Environ/Config.pm

Criterion	Covered	Total	%
statement	48	48	100.0
branch	8	14	57.1
condition			n/a
subroutine	12	12	100.0
pod	2	2	100.0
total	70	76	92.1

package App::Environ::Config;

use 5.008000;
use strict;
use warnings;

our $VERSION = '0.20';

use App::Environ;
use Config::Processor;
use Carp qw( croak );

my @REGD_CONFIG_SECTIONS;
my %CONFIG_SECTIONS_IDX;
my $CONFIG;
my $NEED_CONFIG_INIT = 1;

App::Environ->register( __PACKAGE__,
  initialize   => sub { __PACKAGE__->_initialize(@_) },
  reload       => sub { __PACKAGE__->_reload(@_) },
  'finalize:r' => sub { __PACKAGE__->_finalize(@_) },
);


sub register {
  my $class = shift;
  my @config_sections = @_;

  foreach my $config_section (@config_sections) {
    next if exists $CONFIG_SECTIONS_IDX{$config_section};

    $CONFIG_SECTIONS_IDX{$config_section} = 1;
    push( @REGD_CONFIG_SECTIONS, $config_section );

    $NEED_CONFIG_INIT = 1;
  }

  return;
}

sub instance {
  unless ( defined $CONFIG ) {
    croak __PACKAGE__ . ' must be initialized first';
  }

  return $CONFIG;
}

sub _initialize {
  my $class = shift;

  return unless $NEED_CONFIG_INIT;

  $class->_load;
  undef $NEED_CONFIG_INIT;

  return;
}

sub _reload {
  my $class = shift;

  $class->_load;

  return;
}

sub _finalize {
  undef $CONFIG;
  $NEED_CONFIG_INIT = 1;

  return;
}

sub _load {
  my @config_dirs;
  if ( defined $ENV{APPCONF_DIRS} ) {
    @config_dirs = split /:/, $ENV{APPCONF_DIRS};
  }
  my $interpolate_vars   = $ENV{APPCONF_INTERPOLATE_VARIABLES};
  my $process_directives = $ENV{APPCONF_PROCESS_DIRECTIVES};
  my $export_env         = $ENV{APPCONF_EXPORT_ENV};

  my $config_processor = Config::Processor->new(
    dirs => \@config_dirs,
    $interpolate_vars ? ( interpolate_variables => $interpolate_vars ) : (),
    $process_directives ? ( process_directives => $process_directives ) : (),
    $export_env         ? ( export_env         => $export_env )         : (),
  );

  $CONFIG = $config_processor->load(@REGD_CONFIG_SECTIONS);

  return;
}

1;
__END__