File Coverage

blib/lib/App/Du/Analyze.pm

Criterion	Covered	Total	%
statement	53	58	91.3
branch	10	16	62.5
condition			n/a
subroutine	11	11	100.0
pod	3	3	100.0
total	77	88	87.5

package App::Du::Analyze;
$App::Du::Analyze::VERSION = '0.2.2';
use strict;
use warnings;

use autodie;

use 5.008;

use Getopt::Long qw( GetOptionsFromArray );
use Pod::Usage;

use App::Du::Analyze::Filter;

sub argv
{
    my $self = shift;

    if (@_)
    {
        $self->{argv} = shift;
    }

    return $self->{argv};
}

sub new
{
    my $class = shift;

    my $self = bless {}, $class;

    $self->_init(@_);

    return $self;
}

sub _init
{
    my ( $self, $args ) = @_;

    $self->argv( $args->{argv} );

    return;
}

sub run
{
    my ($self) = @_;

    my $prefix  = "";
    my $depth   = 1;
    my $sort    = 1;
    my $man     = 0;
    my $help    = 0;
    my $version = 0;

    my @argv = @{ $self->argv };

    GetOptionsFromArray(
        \@argv,
        "prefix|p=s" => \$prefix,
        "depth|d=n"  => \$depth,
        "sort"       => \$sort,
        "help|h"     => \$help,
        "man"        => \$man,
        "version"    => \$version,
    ) or pod2usage(2);

    if ($help)
    {
        pod2usage(1);
    }

    if ($man)
    {
        pod2usage( -verbose => 2 );
    }

    if ($version)
    {
        print "analyze-du.pl version $App::Du::Analyze::VERSION\n";
        exit(0);
    }

    my $in_fh;

    my $filename;
    if ( !defined( $filename = $ENV{ANALYZE_DU_INPUT_FN} ) )
    {
        $filename = shift(@argv);
    }

    if ( !defined($filename) )
    {
        $in_fh = \*STDIN;
    }
    else
    {
        open $in_fh, '<', $filename;
    }

    App::Du::Analyze::Filter->new(
        {
            prefix      => $prefix,
            depth       => $depth,
            should_sort => $sort,
        }
    )->filter( $in_fh, \*STDOUT );

    if ( defined($filename) )
    {
        close($in_fh);
    }

    return;
}

1;

__END__