File Coverage

blib/lib/App/Bin/Search.pm

Criterion	Covered	Total	%
statement	60	60	100.0
branch	18	18	100.0
condition	4	6	66.6
subroutine	7	7	100.0
pod	2	2	100.0
total	91	93	97.8

package App::Bin::Search;

use strict;
use warnings;

use Bit::Vector;
use Getopt::Std;

our $VERSION = 0.02;

$| = 1;

# Constructor.
sub new {
	my ($class, @params) = @_;

	# Create object.
	my $self = bless {}, $class;

	# Object.
	return $self;
}

# Run.
sub run {
	my $self = shift;

	# Process arguments.
	$self->{'_opts'} = {
		'b' => 0,
		'h' => 0,
		'v' => 0,
	};
	if (! getopts('bhv', $self->{'_opts'}) || @ARGV < 2
		|| $self->{'_opts'}->{'h'}) {

		print STDERR "Usage: $0 [-b] [-h] [-v] [--version] hex_stream search\n";
		print STDERR "\t-b\t\tPrint in binary (default hexadecimal).\n";
		print STDERR "\t-h\t\tPrint help.\n";
		print STDERR "\t-v\t\tVerbose mode.\n";
		print STDERR "\t--version\tPrint version.\n";
		print STDERR "\thex_stream\tInput hexadecimal stream.\n";
		print STDERR "\tsearch\t\tSearch string (in hex).\n";
		return 1;
	}
	$self->{'_hex_stream'} = $ARGV[0];
	$self->{'_search'} = $ARGV[1];

	$self->{'_bv'} = Bit::Vector->new_Hex(
		length($self->{'_hex_stream'}) * 4,
		$self->{'_hex_stream'},
	);
	$self->{'_bvs'} = Bit::Vector->new_Hex(
		length($self->{'_search'}) * 4,
		$self->{'_search'},
	);

	my $processed_bits = 0;
	if ($self->{'_opts'}->{'v'}) {
		if ($self->{'_opts'}->{'b'}) {
			print "Hexadecimal stream: ".$self->{'_bv'}->to_Bin."\n";
		} else {
			print "Hexadecimal stream: ".$self->{'_bv'}->to_Hex."\n";
		}
		print 'Size of hexadecimal stream: '.$self->{'_bv'}->Size."\n";
		if ($self->{'_opts'}->{'b'}) {
			my $len = length($self->{'_search'}) * 4;
			printf "Looking for: %0${len}s\n", $self->{'_bvs'}->to_Bin;
		} else {
			print 'Looking for: '.$self->{'_search'}."\n";
		}
	}
	while ($self->{'_bv'}->Size) {
		$processed_bits++;
		if ($self->{'_opts'}->{'v'}) {
			if ($self->{'_opts'}->{'b'}) {
				print $self->{'_bv'}->to_Bin.' at '.$processed_bits."bit\n";
			} else {
				print $self->_print_hex.' at '.$processed_bits."bit\n";
			}
		}

		my $s = $self->{'_bvs'}->to_Bin;
		if ($self->{'_bv'}->to_Bin =~ m/^$s/ms) {
			if ($self->{'_opts'}->{'b'}) {
				print 'Found '.$self->{'_bv'}->to_Bin.' at '.$processed_bits." bit\n";
			} else {
				print 'Found '.$self->_print_hex.' at '.$processed_bits." bit\n";
			}
		}
		$self->{'_bv'}->Resize($self->{'_bv'}->Size - 1);
	}

	return 0;
}

sub _print_hex {
	my $self = shift;

	my $tmp = $self->{'_bv'}->Clone;
	my $size = $tmp->Size;
	my $plus = ($size % 4) ? 4 - ($size % 4) : 0;
	$tmp->Resize($size + $plus);
	$tmp->Move_Left($plus);

	return $tmp->to_Hex;
}

1;

__END__