File Coverage

blib/lib/Apertur/SDK/Resource/Upload.pm

Criterion	Covered	Total	%
statement	17	52	32.6
branch	0	14	0.0
condition	0	16	0.0
subroutine	6	8	75.0
pod	2	3	66.6
total	25	93	26.8

package Apertur::SDK::Resource::Upload;

use strict;
use warnings;

use JSON qw(encode_json);
use File::Basename qw(basename);
use Apertur::SDK::Crypto qw(encrypt_image);

sub new {
    my ($class, %args) = @_;
    return bless { http => $args{http} }, $class;
}

sub image {
    my ($self, $uuid, $file, %options) = @_;

    my ($data, $filename);
    if (ref $file eq 'SCALAR') {
        # Raw bytes passed as scalar ref
        $data     = $$file;
        $filename = $options{filename} || 'image.jpg';
    }
    else {
        # File path string
        $filename = $options{filename} || basename($file);
        open my $fh, '<:raw', $file
            or die "Cannot open file '$file': $!\n";
        local $/;
        $data = <$fh>;
        close $fh;
    }

    my $mime_type = $options{mimeType} || $options{mime_type} || 'image/jpeg';

    my @multipart = (
        file => [
            undef,
            $filename,
            'Content-Type' => $mime_type,
            Content        => $data,
        ],
    );

    if ($options{source}) {
        push @multipart, source => $options{source};
    }

    my %headers;
    if ($options{password}) {
        $headers{'x-session-password'} = $options{password};
    }

    return $self->{http}->request(
        'POST', "/api/v1/upload/$uuid/images",
        multipart => \@multipart,
        headers   => \%headers,
    );
}

sub image_encrypted {
    my ($self, $uuid, $file, $public_key, %options) = @_;

    my ($data, $filename);
    if (ref $file eq 'SCALAR') {
        $data     = $$file;
        $filename = $options{filename} || 'image.jpg';
    }
    else {
        $filename = $options{filename} || basename($file);
        open my $fh, '<:raw', $file
            or die "Cannot open file '$file': $!\n";
        local $/;
        $data = <$fh>;
        close $fh;
    }

    my $mime_type = $options{mimeType} || $options{mime_type} || 'image/jpeg';
    my $encrypted = encrypt_image($data, $public_key);

    my $payload = encode_json({
        encryptedKey  => $encrypted->{encrypted_key},
        iv            => $encrypted->{iv},
        encryptedData => $encrypted->{encrypted_data},
        algorithm     => $encrypted->{algorithm},
        filename      => $filename,
        mimeType      => $mime_type,
        source        => $options{source} || 'sdk',
    });

    my %headers = (
        'Content-Type'     => 'application/json',
        'X-Aptr-Encrypted' => 'default',
    );
    if ($options{password}) {
        $headers{'x-session-password'} = $options{password};
    }

    return $self->{http}->request(
        'POST', "/api/v1/upload/$uuid/images",
        body    => $payload,
        headers => \%headers,
    );
}

1;

__END__