File Coverage

blib/lib/AnyEvent/Timer/Cron.pm

Criterion	Covered	Total	%
statement	21	35	60.0
branch	0	4	0.0
condition	0	3	0.0
subroutine	7	11	63.6
pod	0	3	0.0
total	28	56	50.0

package AnyEvent::Timer::Cron;
use Moo;

our $VERSION = '0.001001';
$VERSION = eval $VERSION;

use AnyEvent;
use Scalar::Util qw(weaken);
use Safe::Isa;
use DateTime;
use DateTime::Event::Cron;
use namespace::clean;

has 'cb' => (is => 'ro', required => 1);
has '_cron' => (
    is => 'ro',
    required => 1,
    init_arg => 'cron',
    coerce => sub {
        my $cron = shift;
        if (!ref $cron) {
            $cron = DateTime::Event::Cron->new($cron);
        }
        if ($cron->$_can('next')) {
            return sub { $cron->next(@_) };
        }
        elsif ($cron->$_can('get_next_valid_time_after')) {
            return sub { $cron->get_next_valid_time_after(@_) };
        }
        die "Invalid cron!";
    },
);
has '_timer' => (is => 'rw');

sub BUILD {
    my $self = shift;
    $self->create_timer;
}

sub create_timer {
    my $self = shift;
    weaken $self;
    my $now = DateTime->from_epoch(epoch => AnyEvent->now);
    my $next = $self->next_event($now);
    return
        if not $next;
    my $interval = $next->subtract_datetime_absolute($now)->in_units('nanoseconds') / 1_000_000_000;
    $self->_timer(AnyEvent->timer(
        after => $interval,
        cb => sub {
            $self->{cb}->();
            $self && $self->create_timer;
        },
    ));
}

sub next_event {
    my $self = shift;
    my $now = shift || DateTime->from_epoch(epoch => AnyEvent->now);
    $self->_cron->($now);
}

1;
__END__