File Coverage

blib/lib/AnyEvent/FTP/Server/OS/UNIX.pm

Criterion	Covered	Total	%
statement	11	25	44.0
branch	0	2	0.0
condition			n/a
subroutine	4	7	57.1
pod	2	3	66.6
total	17	37	45.9

package AnyEvent::FTP::Server::OS::UNIX;

use strict;
use warnings;
use 5.010;
use Moo;

# ABSTRACT: UNIX implementations for AnyEvent::FTP
our $VERSION = '0.18'; # VERSION


sub BUILDARGS
{
  my($class, $query) = @_;
  my($name, $pw, $uid, $gid, $quota, $comment, $gcos, $dir, $shell, $expire) = getpwnam $query;
  die "user not found" unless $name;

  return {
    name  => $name,
    uid   => $uid,
    gid   => $gid,
    home  => $dir,
    shell => $shell,
  }
}


has $_ => ( is => 'ro', required => 1 ) for (qw( name uid gid home shell ));


has groups => (
  is      => 'ro',
  lazy    => 1,
  default => sub {
    my $name = shift->name;
    my @groups;
    setgrent;
    my @grent;
    while(@grent = getgrent)
    {
      my($group,$pw,$gid,$members) = @grent;
      foreach my $member (split /\s+/, $members)
      {
        push @groups, $gid if $member eq $name;
      }
    }
    \@groups;
  },
);


sub jail
{
  my($self) = @_;
  chroot $self->home;
  return $self;
}


sub drop_privileges
{
  my($self) = @_;

  $) = join ' ', $self->gid, $self->gid, @{ $self->groups };
  $> = $self->uid;

  $( = $self->gid;
  $< = $self->uid;

  return $self;
}

1;

__END__