File Coverage

lib/AnyEvent/AggressiveIdle.pm

Criterion	Covered	Total	%
statement	50	51	98.0
branch	19	24	79.1
condition	2	6	33.3
subroutine	11	11	100.0
pod	2	2	100.0
total	84	94	89.3

package AnyEvent::AggressiveIdle;

use Carp;
use AnyEvent;
use AnyEvent::Util;

use 5.010001;
use strict;
use warnings;

require Exporter;
our @ISA = qw(Exporter);

our $VERSION        = '0.04';

our @EXPORT         = qw(aggressive_idle);
our @EXPORT_OK      = qw(stop_aggressive_idle aggressive_idle);
our %EXPORT_TAGS    = ( all => [@EXPORT_OK] );

sub stop_aggressive_idle($) {
    our (%IDLE, $WATCHER);

    my ($no) = @_;

    croak "Invalid idle identifier: $no"
        unless $no and !ref($no) and exists $IDLE{$no};

    delete $IDLE{$no};
    undef $WATCHER unless %IDLE;
    return;
}

sub _watcher
{
    our ($WATCHER, $WOBJ, %IDLE);
    # localize keys (because idle processes can change
    # watchers list)
    my @pid = keys %IDLE;
    for my $p (@pid) {
        next unless exists $IDLE{$p};
        next unless defined $IDLE{$p};

        my $cb = $IDLE{$p};
        $IDLE{$p} = undef;

        my $done = 0;
        {
            my $guard = guard {
                $done = 1;
                # do not restart idle process if user has stopped it
                if (exists $IDLE{$p}) {
                    $IDLE{$p} = $cb;
                    return if $WATCHER;
                    $WATCHER = AE::io $WOBJ, 1, \&_watcher;
                }
            };
            $cb->($p, $guard);
        }

        unless ($done) {
            undef $WATCHER unless %IDLE;
        }
    }
}

sub aggressive_idle(&) {
    our ($WOBJ, $WOBJR, %IDLE, $WATCHER, $NO);
    ($WOBJR, $WOBJ) = portable_pipe unless defined $WOBJ;
    $NO = 0 unless defined $NO;

    $WATCHER = AE::io $WOBJ, 1, \&_watcher unless %IDLE;

    my $no = ++$NO;
    $IDLE{$no} = $_[0];

    return unless defined wantarray;
    return guard { stop_aggressive_idle $no };
}



1;
__END__