File Coverage

blib/lib/Template/Plugin/JSON.pm

Criterion	Covered	Total	%
statement	41	42	97.6
branch	4	6	66.6
condition	2	3	66.6
subroutine	14	14	100.0
pod	0	4	0.0
total	61	69	88.4

#!/usr/bin/perl

use 5.008001;

package #
	Template::Plugin::JSON;

our $AUTHORITY = 'cpan:JWRIGHT';
our $ALT = 'Moo';

use Types::Standard ();
use Carp ();
use JSON ();

use Alt::Template::Plugin::JSON::Moo;


use Moo;
use namespace::clean;

extends qw(Template::Plugin);

has context => (
	isa => Types::Standard::Object,
	is  => "ro",
	weak_ref => 1,
);

has json_converter => (
	isa => Types::Standard::Object,
	is  => "lazy",
	lazy_build => 1,
);

has json_args => (
	isa => Types::Standard::HashRef,
	is  => "ro",
	default => sub { {} },
);

sub BUILDARGS {
	my ( $class, $c, @args ) = @_;


	if ( @args == 1 and not ref $args[0] ) {
		warn "Single argument form is deprecated, this module always uses JSON/JSON::XS now";
	}

	my $args = ref $args[0] ? $args[0] : {};

	return { %$args, context => $c, json_args => $args };
}


sub _build_json_converter {
	my $self = shift;

	my $json = JSON->new->allow_nonref(1);

	my $args = $self->json_args;

	for my $method (keys %$args) {
		if ( $json->can($method) ) {
			$json->$method( $args->{$method} );
		}
	}

	return $json;
}

sub json {
	my ( $self, $value ) = @_;

	$self->json_converter->encode($value);
}

sub json_decode {
	my ( $self, $value ) = @_;

	$self->json_converter->decode($value);
}

sub BUILD {
	my $self = shift;
	$self->context->define_vmethod( $_ => json => sub { $self->json(@_) } ) for qw(hash list scalar);
}

no Moo;

__PACKAGE__;

__END__