File Coverage

blib/lib/Alien/libmaxminddb.pm

Criterion	Covered	Total	%
statement	52	53	98.1
branch	4	6	66.6
condition			n/a
subroutine	14	14	100.0
pod	4	7	57.1
total	74	80	92.5

package Alien::libmaxminddb;

# SPDX-License-Identifier: Artistic-1.0-Perl OR GPL-1.0-or-later

use 5.014;
use warnings;
use utf8;

our $VERSION = 2.003;

use File::Spec qw();
use JSON::PP   qw();

sub cflags {
    my $class = shift;

    return $class->config->{cflags};
}

sub libs {
    my $class = shift;

    return $class->config->{libs};
}

sub version {
    my $class = shift;

    return $class->config->{version};
}

sub install_type {
    my $class = shift;

    return $class->config->{install_type};
}

sub config {
    my $class = shift;

    state $config = $class->_config;
    return $config;
}

sub dynamic_libs {
    my $class = shift;

    return;
}

sub bin_dir {
    my $class = shift;

    return;
}

sub _dist_dir_with_subdir {
    my ($class, $subdir) = @_;

    my $dist = $class;
    $dist =~ s/::/-/g;

    my $search_dir = File::Spec->catdir(qw(auto share dist), $dist, $subdir);
    for my $inc (@INC) {
        my $dir = File::Spec->catdir($inc, $search_dir);
        if (-d $dir) {
            return $dir;
        }
    }
    die "unable to find dist share directory for $dist";
}

sub _config {
    my $class = shift;

    my $alien_dir = $class->_dist_dir_with_subdir('_alien');

    my $json_file = File::Spec->catfile($alien_dir, 'alien.json');
    open my $in, '<', $json_file
        or die "Cannot read $json_file";
    my $json = do { local $/; <$in> };
    close $in;

    my $config = JSON::PP::decode_json($json);

    if ($config->{install_type} eq 'share') {
        my $inc_dir = $class->_dist_dir_with_subdir('include');
        $config->{cflags} = join ' ', "-I$inc_dir", $config->{cflags};
        my $lib_dir = $class->_dist_dir_with_subdir('lib');
        $config->{libs} = join ' ', "-L$lib_dir", $config->{libs};
    }

    return $config;
}

1;
__END__