File Coverage

blib/lib/Alien/Role/Alt.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	6	6	100.0
condition	2	3	66.6
subroutine	7	7	100.0
pod	1	1	100.0
total	47	48	97.9

package Alien::Role::Alt;

use strict;
use warnings;
use 5.008001;
use Role::Tiny;
use Storable ();
use Carp ();

# ABSTRACT: Alien::Base role that supports alternates
our $VERSION = '0.03'; # VERSION


sub alt
{
  my($old, $name) = @_;
  my $new = ref $old ? (ref $old)->new : $old->new;

  my $orig;

  if(ref($old) && defined $old->{_alt})
  { $orig = $old->{_alt}->{orig} }
  else
  { $orig = $old->runtime_prop }

  my $runtime_prop = Storable::dclone($orig);

  if($runtime_prop->{alt}->{$name})
  {
    foreach my $key (keys %{ $runtime_prop->{alt}->{$name} })
    {
      $runtime_prop->{$key} = $runtime_prop->{alt}->{$name}->{$key};
    }
  }
  else
  {
    Carp::croak("no such alt: $name");
  }

  $new->{_alt} = {
    runtime_prop => $runtime_prop,
    orig         => $orig,
  };

  $new;
}

around runtime_prop => sub {
  my $orig = shift;

  my($self) = @_;

  if(ref($self) && defined $self->{_alt})
  {
    return $self->{_alt}->{runtime_prop};
  }
  else
  {
    return $orig->($self);
  }
};

1;

__END__