File Coverage

blib/lib/Alias/Any.pm

Criterion	Covered	Total	%
statement	38	56	67.8
branch	4	10	40.0
condition	2	4	50.0
subroutine	11	13	84.6
pod			n/a
total	55	83	66.2

package Alias::Any;

use 5.012;
use warnings;

our $VERSION = '0.000006';

use Keyword::Simple;

# Make 'keyword' and 'unkeyword' no-ops, unless Keyword::Declare is later loaded...
BEGIN {
    sub _delete_source { my $ref = shift; $$ref =~ s{ \A .*? [#]END_OF_ALIAS }{}xms; }
    Keyword::Simple::define(   keyword => \&_delete_source );
    Keyword::Simple::define( unkeyword => \&_delete_source );
}

sub import {
    # Below 5.22, alias keyword just injects Data::Alias...
    if ($^V <  5.022) {
        Keyword::Simple::define(
            alias => sub {
                my $ref = shift;
                $$ref = q{use Data::Alias; Data::Alias::alias} . $$ref;
            }
        );
    }

    # Above 5.22, alias keyword replaced with built-in syntax...
    use if $^V >= 5.022, 'Keyword::Declare';

    keyword alias (Variable|VariableDeclaration $variable, '=', Expr $expr) {{{
        use feature 'refaliasing';
        no warnings 'experimental::refaliasing';
        \<{$variable}> = \<{$expr}>
    }}} #END_OF_ALIAS
}

sub unimport {
    # Below 5.22, alias keyword is undefined by Keyword::Simple...
    if ($^V < 5.022) {
        Keyword::Simple::undefine('alias');
        if ($Keyword::Simple::VERSION < 0.04) {
            $^H{'Keyword::Simple/keywords'} =~ s{ alias:(?:\d+|-\d*)}{}g;
        }
    }

    # Above 5.22, alias keyword is unkeyworded by Keyword::Declare...
    use if $^V >= 5.022, 'Keyword::Declare';
    unkeyword alias; #END_OF_ALIAS
}


1; # Magic true value required at end of module
__END__