File Coverage

blib/lib/Algorithm/Graphs/Reachable/Tiny.pm

Criterion	Covered	Total	%
statement	42	43	97.6
branch	18	22	81.8
condition			n/a
subroutine	6	6	100.0
pod	1	1	100.0
total	67	72	93.0

package Algorithm::Graphs::Reachable::Tiny;

use 5.008;
use strict;
use warnings;

use Carp;
use Exporter 'import';

our $VERSION = '0.11';

our @EXPORT_OK = qw(all_reachable);


sub all_reachable {
  @_ == 2 or croak("Need exactly two arguments!");
  my ($graph, $nodes) = @_;
  my %visited = ref($nodes) eq "ARRAY" ? map {$_ => undef} @{$nodes} : %{$nodes};
  return {} unless %visited;
  my @queue = keys(%visited);
  if (ref($graph) eq 'HASH') {
  return \%visited unless %{$graph};
    while (defined(my $v = shift(@queue))) {
      if (exists($graph->{$v})) { ## we need this if() to avoid autovivification!
        foreach my $s (keys(%{$graph->{$v}})) {
          if (!exists($visited{$s})) {
            $visited{$s} = undef;
            push(@queue, $s);
          }
        }
      }
    }
  }
  elsif (ref($graph) eq 'ARRAY') {
  return \%visited unless @{$graph};
    while (defined(my $v = shift(@queue))) {
      if (defined($graph->[$v])) {
        foreach my $s (keys(%{$graph->[$v]})) {
          if (!exists($visited{$s})) {
            $visited{$s} = undef;
            push(@queue, $s);
          }
        }
      }
    }
  } else {
    croak("Arg 1 must be an ARRAY or HASH reference");
  }
  return \%visited;
}




1; # End of Algorithm::Graphs::Reachable::Tiny


__END__