File Coverage

blib/lib/Ado/Command/generate/crud.pm

Criterion	Covered	Total	%
statement	55	55	100.0
branch	5	6	83.3
condition	6	15	40.0
subroutine	8	8	100.0
pod	2	2	100.0
total	76	86	88.3

package Ado::Command::generate::crud;
use Mojo::Base 'Ado::Command::generate';
use Mojo::Util qw(camelize class_to_path decamelize);
use Getopt::Long qw(GetOptionsFromArray :config no_auto_abbrev no_ignore_case);
use Time::Piece ();
use List::Util qw(first);
File::Spec::Functions->import(qw(catfile catdir splitdir));

has description => "Generates directory structures for Ado-specific CRUD..\n";
has usage => sub { shift->extract_usage };

has routes => sub {
    $_[0]->{routes} = [];
    foreach my $t (@{$_[0]->args->{tables}}) {
        my $controller = camelize($t);
        my $route      = decamelize($controller);
        push @{$_[0]->{routes}},
          { route => "/$route",
            via   => ['GET'],
            to    => "$route#list",
          },
          { route => "/$route/list",
            via   => ['GET'],
            to    => "$route#list",
          },
          { route => "/$route/read/:id",
            via   => [qw(GET)],
            to    => "$route#read",
          },
          { route => "/$route/create",
            via   => [qw(GET POST)],
            to    => "$route#create",
            over  => {authenticated => 1},
          },
          { route => "/$route/update/:id",
            via   => [qw(GET PUT)],
            to    => "$route#update",
            over  => {authenticated => 1},
          },
          { route => "/$route/delete/:id",
            via   => [qw(GET DELETE)],
            to    => "$route#delete",
            over  => {authenticated => 1},
          };
    }
    return $_[0]->{routes};
};

sub initialise {
    my ($self, @args) = @_;
    return $self if $self->{_initialised};
    my $args = $self->args({tables => []})->args;

    GetOptionsFromArray(
        \@args,
        'C|controller_namespace=s' => \$args->{controller_namespace},

        #'d|dsn=s'                  => \$args->{dsn},
        'L|lib=s'             => \$args->{lib},
        'M|model_namespace=s' => \$args->{model_namespace},

        #'N|no_dsc_code'            => \$args->{no_dsc_code},
        'O|overwrite' => \$args->{overwrite},

        #'P|password=s'             => \$args->{password},
        'T|templates_root=s' => \$args->{templates_root},
        't|tables=s@'        => \$args->{tables},
        'H|home_dir=s'       => \$args->{home_dir},

        #'U|user=s'                 => \$args->{user},
    );

    @{$args->{tables}} = split(/\,/, join(',', @{$args->{tables}}));
    Carp::croak $self->usage unless scalar @{$args->{tables}};
    my $app = $self->app;
    $args->{controller_namespace} //= $app->routes->namespaces->[0];
    $args->{model_namespace} //=
      (first { ref($_) eq 'HASH' and $_->{name} eq 'DSC' } @{$app->config('plugins')})
      ->{config}{namespace};
    $args->{home_dir}       //= $app->home;
    $args->{lib}            //= catdir($args->{home_dir}, 'lib');
    $args->{templates_root} //= $app->renderer->paths->[0];
    $self->{_initialised} = 1;
    return $self;
}

sub run {
    my ($self) = shift->initialise(@_);
    my $args   = $self->args;
    my $app    = $self->app;

    foreach my $t (@{$args->{tables}}) {

        # Controllers
        my $class_name = camelize($t);
        $args->{class} = $args->{controller_namespace} . '::' . $class_name;
        my $c_file = catfile($args->{lib}, class_to_path($args->{class}));
        $args->{t} = lc $t;
        $self->render_to_file('class', $c_file, $args);

        # Templates
        my $template_dir  = decamelize($class_name);
        my $template_root = $args->{templates_root};
        my $t_file        = catfile($template_root, $template_dir, 'list.html.ep');
        $self->render_to_file('list_template', $t_file, $args);
        $t_file = catfile($template_root, $template_dir, 'create.html.ep');
        $self->render_to_file('create_template', $t_file, $args);
        $t_file = catfile($template_root, $template_dir, 'read.html.ep');
        $self->render_to_file('read_template', $t_file, $args);
        $t_file = catfile($template_root, $template_dir, 'delete.html.ep');
        $self->render_to_file('delete_template', $t_file, $args);
    }    # end foreach tables

    return $self;
}


1;


=pod

=encoding utf8

=head1 NAME

Ado::Command::generate::crud - Generates MVC set of files

=head1 SYNOPSIS

  Usage:
  #on the command-line
  # for one or more tables.
  $ bin/ado generate crud --tables='news,articles'

  #programatically
  use Ado::Command::generate::crud;
  my $v = Ado::Command::generate::crud->new;
  $v->run(-t => 'news,articles');

=head1 DESCRIPTION

B
The generated code is not even expected to work properly.>

L generates directory structure for
a fully functional
L
set of files, based on existing tables in the database.
You only need to create the tables. The Model (M) classes are generated on the fly
from the tables when the controller classes are loaded by L for the first time.
You can dump them to disk if you want using the C script that
comes with L. You may decide to use only L
via the C<$c-Edbix> helper or L via C<$c-Edbix-Edbh>.
That's up to you.

This tool's purpose is to promote
L
by generating the boilerplate code for controllers (C)
and help programmers new to L and L to quickly create
well structured, fully functional applications.

In the generated actions you will find I code
for reading, creating, updating and deleting records from the tables you
specified on the command-line.

The generated code is just boilerplate to give you a jump start, so you can
concentrate on writing your business-specific code. It is assumed that you will
modify the generated code to suit your specific needs.

=head1 OPTIONS

Below are the options this command accepts, described in L notation.

=head2 C|controller_namespace=s

Optional. The namespace for the controller classes to be generated.
Defaults to  Croutes-Enamespaces-E[0]>, usually
L. If you decide to use another namespace for the controllers,
do not forget to add it to the list Croutes-Enamespaces>
in C or your plugin configuration file.

=head2 H|home_dir=s

Defaults to C<$ENV{MOJO_HOME}> (which is Ado home directory).
Used to set the root directory to which the files
will be dumped when L.

=head2 L|lib=s

Defaults to C relative to the C<--home_dir> directory.
If you installed L in some custom path and you wish to generate your controllers into
e.g. C, use this option. Do not forget to add this
directory to C<$ENV{PERL5LIB}>, so the classes can be found and loaded.

=head2 M|model_namespace=s

Optional. The namespace for the model classes to be generated.
Defaults to L. If you wish however to use another namespace
for another database, you will have to add another item for
L to the list of loaded plugins in C
or in your plugin configuration. Yes, multiple database connections/schemas
are supported.

=head2 T|templates_root=s

Defaults to Crenderer-Epaths-E[0]>. This is usually
C directory. If you want to use another directory,
do not forget to add it to the Crenderer-Epaths> list
in your configuration file.

=head2 t|tables=s@

Mandatory. List of tables separated by commas for which controllers should be generated.

=head1 ATTRIBUTES

L inherits all attributes from
L and implements the following new ones.

=head2 description

  my $description = $command->description;
  $command        = $command->description('Foo!');

Short description of this command, used for the command list.

=head2 routes

  $self->routtes();

Returns an ARRAY reference containing routes, prepared after C<$self-Eargs-E{tables}>.

Altough L already has defined generic routes for CRUD,
this attribute contains more specific routes, that will secure the C,
C and C actions, so they are available only to an
authenticated user. This attribute is used for generating routes in
L.
After generating a plugin you should end up with a
L
service. The generated code uses
L. For details see
L.

=head2 usage

  my $usage = $command->usage;
  $command  = $command->usage('Foo!');

Usage information for this command, used for the help screen.

=head1 METHODS

L inherits all methods from
L and implements the following new ones.

=head2 initialise

  sub run {
      my ($self) = shift->initialise(@_);
      #...
  }

Parses arguments and prepares the command to be run. Calling this method for the second time has no effect.
Returns C<$self>.

=head2 run

  Ado::Command::generate::crud->new(app=>$app)->run(@ARGV);

Run this command.

=head1 SEE ALSO

L,
L,
L, L,
L, L,
L L,
L, L

=head1 AUTHOR

Красимир Беров (Krasimir Berov)

=head1 COPYRIGHT AND LICENSE

Copyright 2014 Красимир Беров (Krasimir Berov).

This program is free software, you can redistribute it and/or
modify it under the terms of the
GNU Lesser General Public License v3 (LGPL-3.0).
You may copy, distribute and modify the software provided that
modifications are open source. However, software that includes
the license may release under a different license.

See http://opensource.org/licenses/lgpl-3.0.html for more information.

=cut

__DATA__