File Coverage

blib/lib/Acme/Odometer.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

use strict;
use warnings;

use 5.006;

package Acme::Odometer;
$Acme::Odometer::VERSION = '0.0.4';
use Moo 1.001;
use namespace::clean;

use GD;
use Memoize;
use MooX::Types::MooseLike::Numeric qw(PositiveInt PositiveOrZeroInt);
use Path::Class qw( file );

memoize( '_digit_as_image' );

has asset_path => (
    is       => 'ro',
    required => 1,
);

has file_extension => (
    is       => 'ro',
    required => 0,
    default  => 'gif',
);

has _digit_height => (
    is       => 'ro',
    isa      => PositiveInt,
    required => 0,
    lazy     => 1,
    builder  => '_build_height',
);

has _digit_width => (
    is       => 'ro',
    isa      => PositiveInt,
    required => 0,
    lazy     => 1,
    builder  => '_build_width',
);

has _first_image => (
    is       => 'ro',
    init_arg => undef,
    lazy     => 1,
    builder  => '_build_first_image',
);

has _i => (
    is       => 'ro',
    isa      => PositiveOrZeroInt,
    required => 0,
    init_arg => undef,
    writer   => '_set_i',
);

sub _build_width {
    my $self = shift;
    return $self->_first_image->width;
}

sub _build_height {
    my $self = shift;
    return $self->_first_image->height;
}

sub _build_first_image {
    my $self = shift;
    return $self->_digit_as_image( substr( $self->_i, 0, 1 ) );
}

sub _digit_as_image {
    my $self = shift;
    my $digit = sprintf( "%i.%s", shift(), $self->file_extension );
    return GD::Image->new( file( $self->asset_path, $digit )->stringify );
}

sub image {
    my $self = shift;
    $self->_set_i( shift() );

    my $total_width = $self->_digit_width * length $self->_i;
    my $im          = GD::Image->new( $total_width, $self->_digit_height );
    my $percent     = 100;

    my $pos = 0;
    foreach my $digit ( split //, $self->_i ) {
        $im->copyMergeGray(
            $self->_digit_as_image( $digit ),
            $pos * $self->_digit_width,
            0, 0, 0, $self->_digit_width, $self->_digit_height, $percent
        );
        $pos++;
    }

    return $im;
}

1;

# ABSTRACT: Create graphical web counters

__END__