File Coverage

blib/lib/ASP4/Config.pm

Criterion	Covered	Total	%
statement	57	59	96.6
branch	8	12	66.6
condition			n/a
subroutine	9	10	90.0
pod	0	3	0.0
total	74	84	88.1

package ASP4::Config;

use strict;
use warnings 'all';
use Carp 'confess';
use base 'ASP4::ConfigNode';


sub new
{
  my ($class, $ref, $root) = @_;

  my $s = $class->SUPER::new( $ref );

  $s->init_server_root( $root );

  $s->_init_inc();

  my $vars = $s->system->env_vars;
  foreach my $var ( keys %$vars )
  {
    $ENV{$var} = $vars->{$var};
  }# end foreach()

  map { $s->load_class( $_ ) } $s->system->load_modules;

  return $s;
}# end new()


sub _init_inc
{
  my $s = shift;

  my %saw = map { $_ => 1 } @INC;
  push @INC, grep { ! $saw{$_}++ } ( $s->system->libs, $s->web->handler_root, $s->web->page_cache_root );
}# end _init_inc()


sub init_server_root
{
  my ($s, $root) = @_;

  no warnings 'uninitialized';
  foreach( @{ $s->{system}->{libs} } )
  {
    $_ =~ s/\@ServerRoot\@/$root/;
  }# end foreach()

  my $settings = $s->{system}->{settings};
  foreach( keys %$settings )
  {
    $settings->{$_} =~ s/\@ServerRoot\@/$root/;
  }# end foreach()

  foreach my $key (qw/ application handler www page_cache /)
  {
    $s->{web}->{"$key\_root"} =~ s/\@ServerRoot\@/$root/;
    $s->{web}->{"$key\_root"} =~ s{\\\\}{\\}g;
  }# end foreach()

  mkdir( $s->{web}->{page_cache_root}, 0777 )
    unless -d $s->{web}->{page_cache_root};
  chmod( 0777, $s->{web}->{page_cache_root} );
  confess "Folder '$s->{web}->{page_cache_root}' does not exist and cannot be created"
    unless -d $s->{web}->{page_cache_root};

  (my $compiled_root = $s->{web}->{page_cache_root} . '/' . $s->{web}->{application_name}) =~ s/::/\//g;
  my $folder = "";
  foreach my $part ( grep { $_ } split /\//, $compiled_root )
  {
    $folder .= "/$part";
    unless( -d $folder )
    {
      mkdir($folder);
      chmod(0777, $folder)
    }# end unless()
    confess "Folder '$folder' does not exist and cannot be created"
      unless -d $folder;
  }# end foreach()

  confess "Folder '$folder' exists but cannot be written to"
    unless -w $folder;
}# end init_server_root()


sub load_class
{
  my ($s, $class) = @_;

  (my $file = "$class.pm") =~ s/::/\//g;
  eval { require $file }
    or confess "Cannot load $class: $@";
}# end load_class()


sub DESTROY
{
  my $s = shift;
  undef(%$s);
}


1;# return true:

=pod

=head1 NAME

ASP4::Config - Central configuration for ASP4

=head1 SYNOPSIS

  # Settings:
  $Config->system->settings->some_setting;
  $Config->system->settings->another_setting;

  # Error-handling:
  $Config->errors->error_handler;
  $Config->errors->mail_errors_to;
  $Config->errors->mail_errors_from;
  $Config->errors->smtp_server;

  # Web:
  $Config->web->application_name;
  $Config->web->application_root;
  $Config->web->www_root;
  $Config->web->handler_root;
  $Config->web->media_manager_upload_root;
  $Config->web->page_cache_root;

  # Data Connections:
  foreach my $conn ( map { $Config->data_connections->$_ } qw/ session application main / )
  {
    my $dbh = DBI->connect(
      $conn->dsn,
      $conn->username,
      $conn->password
    );
  }# end foreach()

=head1 JSON Config File

ASP4::ASP keeps all of its configuration inside of C

Here is an example:

  {
    "system": {
      "post_processors": [

      ],
      "libs": [
        "@ServerRoot@/lib"
      ],
      "load_modules": [
        "DBI",
        "DBD::SQLite"
      ],
      "env_vars": {
        "myvar":        "Some-Value",
        "another_var":  "Another Value"
      },
      "settings": {
        "foo": "bar",
        "baz": "bux"
      }
    },
    "errors": {
      "error_handler":    "ASP4::ErrorHandler",
      "mail_errors_to":   "[e-mail]",
      "mail_errors_from": "root@localhost",
      "smtp_server":      "localhost"
    },
    "web": {
      "application_name": "DefaultApp",
      "application_root": "@ServerRoot@",
      "www_root":         "@ServerRoot@/htdocs",
      "handler_root":     "@ServerRoot@/handlers",
      "page_cache_root":  "/tmp/PAGE_CACHE",
      "handler_resolver": "ASP4::HandlerResolver",
      "handler_runner":   "ASP4::HandlerRunner",
      "filter_resolver":  "ASP4::FilterResolver",
      "request_filters": [
        {
          "uri_match":  "^/.*",
          "class":      "My::Filter"
        }
      ],
      "disable_persistence": [
        {
          "uri_match":            "^/handlers/dev\\.speed",
          "disable_session":      true
        },
        {
          "uri_match":            "^/index\\.asp",
          "disable_session":      true
        }
      ]
    },
    "data_connections": {
      "session": {
        "manager":          "ASP4::SessionStateManager",
        "cookie_name":      "session-id",
        "cookie_domain":    ".mysite.com",
        "session_timeout":  30,
        "dsn":              "DBI:SQLite:dbname=/tmp/db_asp4",
        "username":         "",
        "password":         ""
      },
      "main": {
        "dsn":      "DBI:SQLite:dbname=/tmp/db_asp4",
        "username": "",
        "password": ""
      }
    }
  }

=head1 BUGS

It's possible that some bugs have found their way into this release.

Use RT L to submit bug reports.

=head1 HOMEPAGE

Please visit the ASP4 homepage at L to see examples
of ASP4 in action.

=head1 AUTHOR

John Drago

=head1 COPYRIGHT

Copyright 2008 John Drago.  All rights reserved.

=head1 LICENSE

This software is Free software and is licensed under the same terms as perl itself.

=cut