File Coverage

lib/warnings/MaybeFatal.pm

Criterion	Covered	Total	%
statement	35	43	81.4
branch	9	18	50.0
condition	0	3	0.0
subroutine	13	14	92.8
pod			n/a
total	57	78	73.0

use 5.008004;
use strict;
use warnings;

package warnings::MaybeFatal;

our $AUTHORITY = 'cpan:TOBYINK';
our $VERSION   = '0.005';

BEGIN {
	if ( $] < 5.012 ) {
		require Lexical::SealRequireHints;
		Lexical::SealRequireHints->import;
	}
};

use B::Hooks::EndOfScope;
use Carp qw(croak);

BEGIN {
	B::Hooks::EndOfScope->Module::Implementation::implementation_for eq 'XS'
		or croak("Pure Perl implementation of B::Hooks::EndOfScope not supported");
};

sub _my_hints
{
	$^H |= 0x20000;
	\%^H;
}

sub import
{
	_my_hints->{+__PACKAGE__} = 1;

	# Keep original signal handler
	my $orig = $SIG{__WARN__};
	if (!ref($orig))
	{
		$orig = ($orig eq 'DEFAULT' or $orig eq 'IGNORE')
			? undef
			: do {
				no strict 'refs';
				exists(&{'main::'.$orig}) ? \&{'main::'.$orig} : undef;
			};
		$orig = sub { warn(@_) } unless defined $orig;
	}

	my @warnings;
	$SIG{__WARN__} = sub {
		_my_hints->{+__PACKAGE__}
			? push(@warnings, $_[0])
			: $orig->(@_);
	};

	on_scope_end {
		$SIG{__WARN__} = $orig;
		if (@warnings == 1)
		{
			die($warnings[0]);
		}
		elsif (@warnings)
		{
			$orig->($_) for @warnings;
			local $Carp::CarpLevel = $Carp::CarpLevel + 1;
			croak("Compile time warnings");
		}
	};
}

sub unimport
{
	_my_hints->{+__PACKAGE__} = 0;
}

1;

__END__