File Coverage

blib/lib/results.pm

Criterion	Covered	Total	%
statement	59	59	100.0
branch	11	14	78.5
condition	2	3	66.6
subroutine	19	19	100.0
pod	4	5	80.0
total	95	100	95.0

use 5.014;
use strict;
use warnings;

use Carp ();
use Devel::StrictMode ();
use Scalar::Util ();

package results;

our $AUTHORITY = 'cpan:TOBYINK';
our $VERSION   = '0.006';

use Exporter::Shiny qw( err is_result ok ok_list );
our @EXPORT = qw( err ok );

use Attribute::Handlers;

require Result::Err;
require Result::Ok;
require Result::OkList;

use constant {
	ERR_CLASS     => 'Result::Err',
	OK_CLASS      => 'Result::Ok',
	OK_LIST_CLASS => 'Result::OkList',
};

sub err {
	Carp::croak("Void context forbidden here") unless defined wantarray;
	ERR_CLASS->new( @_ );
}

sub is_result {
	Scalar::Util::blessed( $_[0] )
		and $_[0]->can( 'DOES' )
		and $_[0]->DOES( 'Result::Trait' )
}

sub ok {
	Carp::croak("Void context forbidden here") unless defined wantarray;
	OK_CLASS->new( @_ );
}

sub ok_list {
	Carp::croak("Void context forbidden here") unless defined wantarray;
	OK_LIST_CLASS->new( @_ );
}

sub UNIVERSAL::Result : ATTR(CODE) {
	Devel::StrictMode::STRICT or return;

	my ( $package, $symbol, $referent, $attr, $data ) = @_;
	my $name = *{$symbol}{NAME};

	no strict 'refs';
	no warnings 'redefine';

	if ( ref($data) eq 'ARRAY' ) {
		require Type::Utils;
		my $type = Type::Utils::dwim_type( $data->[0], for => $package );

		*{"$package\::$name"} = sub {
			my $return = $referent->( @_ );
			die "Function '$name' declared to return a Result, but returned: $return"
				unless is_result( $return );
			$return->type( $type );
		};
	}
	else {
		*{"$package\::$name"} = sub {
			my $return = $referent->( @_ );
			die "Function '$name' declared to return a Result, but returned: $return"
				unless is_result( $return );
			$return;
		};
	}
}

1;

__END__