File Coverage

blib/lib/filename.pm

Criterion	Covered	Total	%
statement	23	24	95.8
branch	11	16	68.7
condition	7	13	53.8
subroutine	4	4	100.0
pod	1	1	100.0
total	46	58	79.3

use strict;
use warnings;

package filename v0.20.008;
# ABSTRACT: Perl module to load files at compile-time, without BEGIN blocks.


use Carp 1.50 ();


my $error = sub { };    # Private sub

# Modified version of the code as specified in `perldoc -f require`
*import = \&require;
sub require {
    eval { $_[0]->isa(__PACKAGE__) } && shift
        || Carp::croak( $_[0], " is not a ", __PACKAGE__ );
    my $filename = @_ ? shift : $_;
    Carp::croak("Null filename used") unless length($filename);

    return $INC{$filename} if ( exists $INC{$filename} );

    if ( $filename =~ m!\A/! ) {
        goto NOT_INC if $^V < v5.17.0 && !-r $filename;
        return do($filename) || $error->($filename);
    }
    foreach my $prefix (@INC) {
        next unless -f ( my $fullpath = "$prefix/$filename" );
        next if $^V < v5.17.0 && !-r _;
        my $result = do $fullpath;
        $INC{$filename} = delete $INC{$fullpath};
        return $result || $error->( $filename => $fullpath );
    }
    NOT_INC:
        Carp::croak("Can't locate $filename in \@INC (\@INC contains: @INC)");
}

# Private sub
$error = sub {
    my $filename = @_ ? shift : $_;
    my $fullpath = @_ ? shift : $filename;

    $INC{$filename} = undef;

    $@ && Carp::croak( $@, "Compilation failed in require" );

    $! && Carp::croak(
        "Can't locate $filename:   ",
        $^V >= v5.21.0 ? "$fullpath: " : (),
        "$!"
    );

    delete $INC{$filename};
    Carp::croak( $filename, " did not return a true value" );
};

1;

__END__