File Coverage

blib/lib/Zeal.pm

Criterion	Covered	Total	%
statement	16	18	88.8
branch			n/a
condition			n/a
subroutine	6	6	100.0
pod			n/a
total	22	24	91.6

package Zeal;

use 5.014000;
use strict;
use warnings;
use re '/s';

our $VERSION = '0.001';

use File::Spec::Functions qw/catfile/;

use Zeal::Docset;
use Zeal::Document;

sub new {
	my ($class, $path) = @_;
	$path //= $ENV{ZEAL_PATH};
	my $self = bless {sets => {}}, $class;
	if ($path) {
		$self->add($_) for split /:/, $path;
	}
	$self
}

sub add {
	my ($self, $path) = @_;
	return unless -d $path;
	if ($path =~ /[.]docset$/) {
		my $ds = Zeal::Docset->new($path);
		$self->{sets}{$ds->family} //= [];
		push @{$self->{sets}{$ds->family}}, $ds;
	} else {
		my $dir;
		opendir $dir, $path;
		my @entries = grep { !/^[.]{1,2}$/ } readdir $dir;
		closedir $dir;
		$self->add(catfile $path, $_) for @entries
	}
}

sub sets {
	my ($self, $family) = @_;
	return map { @$_ } values %{$self->{sets}} unless $family;
	die "No docsets in family '$family'\n" unless $self->{sets}{$family};
	@{$self->{sets}{$family}}
}

sub query {
	my ($self, $query, $family) = @_;
	($family, $query) = split /:/, $query, 2 if !$family && $query =~ /^\w+:[^:]/;
	my @res = map { $_->query($query) } $self->sets($family);
	wantarray ? @res : $res[0]
}

1;
__END__