File Coverage

blib/lib/Zabbix2/API/Graph.pm

Criterion	Covered	Total	%
statement	32	85	37.6
branch	0	10	0.0
condition	0	8	0.0
subroutine	11	23	47.8
pod	5	5	100.0
total	48	131	36.6

package Zabbix2::API::Graph;

use strict;
use warnings;
use 5.010;
use Carp;
use autodie;
use utf8;

use URI;
use Params::Validate qw/validate :types/;

use Moo;
extends qw/Exporter Zabbix2::API::CRUDE/;

# extracted from frontends/php/include/defines.inc.php
use constant {
    GRAPH_TYPE_NORMAL => 0,
    GRAPH_TYPE_STACKED => 1,
    GRAPH_TYPE_PIE => 2,
    GRAPH_TYPE_EXPLODED => 3,
};

our @EXPORT_OK = qw/GRAPH_TYPE_NORMAL GRAPH_TYPE_STACKED GRAPH_TYPE_PIE GRAPH_TYPE_EXPLODED/;

our %EXPORT_TAGS = (
    graphtypes => [ qw/GRAPH_TYPE_NORMAL GRAPH_TYPE_STACKED GRAPH_TYPE_PIE GRAPH_TYPE_EXPLODED/ ]
    );

use Zabbix2::API::GraphItem;

has 'graphitems' => (is => 'rw');
has 'color_wheel' => (is => 'ro',
                      clearer => 1,
                      lazy => 1,
                      builder => '_build_color_wheel');

sub make_color_wheel {
    my ($class, $colors) = @_;
    return sub {
        state $iterator = 0;
        my $color = $colors->[$iterator];
        $iterator++;
        $iterator = $iterator % scalar(@{$colors});
        return $color;
    };
}

sub _build_color_wheel {
    my $self = shift;
    # TODO pick nicer colors
    return $self->make_color_wheel([qw/1C1CCC 1CCC1C CC1C1C FDFD49 9A1C9A 1CCCCC FD8C1C/]);
}

sub add_items {
    my ($self, @items) = @_;
    my @graphitems = map { Zabbix2::API::GraphItem->new(
                               root => $self->root,
                               data => { itemid => $_->id,
                                         color => $self->color_wheel->() }) } @items;
    if ($self->id) {
        # has been sync'd with server at least once.
        push @{$self->graphitems}, @graphitems;
    } else {
        # assume graphitems is empty, avoids fetching the graphitems
        # list which we cannot do without a graphid
        $self->graphitems(\@graphitems);
    }
    return @graphitems;
}

sub id {
    ## mutator for id
    my ($self, $value) = @_;
    if (defined $value) {
        $self->data->{graphid} = $value;
        return $self->data->{graphid};
    } else {
        return $self->data->{graphid};
    }
}

sub _readonly_properties {
    ## hash of item properties that cannot be updated; they will be
    ## removed before pushing the item to the server
    return {
        graphid => 1,
        flags => 1,
        templateid => 1,
    };
}
sub _prefix {
    my ($class, $suffix) = @_;
    if ($suffix) {
        return 'graph'.$suffix;
    } else {
        return 'graph';
    }
}

sub _extension {
    return (output => 'extend',
            selectHosts => ['hostid'],
            selectGraphItems => 'extend');
}

sub name {
    return shift->data->{name} || '???';
}

sub url {
    my $self = shift;
    my $base_url = $self->{root}->{server};
    my %args = validate(@_, { width => { type => SCALAR, optional => 1, regex => qr/^\d+$/ },
                              height => { type => SCALAR, optional => 1, regex => qr/^\d+$/ },
                              period => { type => SCALAR, optional => 1, regex => qr/^\d+$/ },
                              start_time => { type => SCALAR, optional => 1, regex => qr/^\d{14}$/ } });

    my $url = URI->new($base_url);
    my @path_segments = $url->path_segments;

    # replace api_jsonrpc.php with the chart generation page
    if ($self->data->{graphtype} == GRAPH_TYPE_NORMAL
        or $self->data->{graphtype} == GRAPH_TYPE_STACKED) {
        $path_segments[-1] = 'chart2.php';
    } elsif ($self->data->{graphtype} == GRAPH_TYPE_PIE
        or $self->data->{graphtype} == GRAPH_TYPE_EXPLODED) {
        $path_segments[-1] = 'chart6.php';
    } else {
        croak(sprintf(q{Unknown graph type %d, cannot guess URL},
                      $self->data->{graphtype}));
    }

    $url->path_segments(@path_segments);

    $url->query_form(graphid => $self->id, %args);

    return $url;
}

sub _map_graphitems_to_property {
    my ($self) = @_;
    $self->data->{gitems} = [ map { $_->data } @{$self->graphitems} ];
    return;
}

sub _map_property_to_graphitems {
    my ($self) = @_;
    my @graphitems = map { Zabbix2::API::GraphItem->new(root => $self->root,
                                                        data => $_) } @{$self->data->{gitems}};
    $self->graphitems(\@graphitems);
    return;
}

before 'create' => \&_map_graphitems_to_property;
before 'update' => \&_map_graphitems_to_property;
after 'pull' => \&_map_property_to_graphitems;
around 'new' => sub {
    my ($orig, @rest) = @_;
    my $graph = $orig->(@rest);
    $graph->_map_property_to_graphitems;
    return $graph;
};

1;
__END__