File Coverage

blib/lib/Zabbix2/API/Application.pm

Criterion	Covered	Total	%
statement	20	39	51.2
branch	0	4	0.0
condition	0	2	0.0
subroutine	7	14	50.0
pod	2	2	100.0
total	29	61	47.5

package Zabbix2::API::Application;

use strict;
use warnings;
use 5.010;
use Carp;
use autodie;
use utf8;

use Moo::Lax;
extends qw/Zabbix2::API::CRUDE/;

has 'items' => (is => 'ro',
                lazy => 1,
                builder => '_fetch_items');
has 'host' => (is => 'ro',
               lazy => 1,
               builder => '_fetch_host');

sub id {
    ## mutator for id
    my ($self, $value) = @_;
    if (defined $value) {
        $self->data->{applicationid} = $value;
        return $self->data->{applicationid};
    } else {
        return $self->data->{applicationid};
    }
}

sub _readonly_properties {
    return {
        applicationid => 1,
        # 2.2 uses templateids, 2.0 uses templateid, neither are updatable
        templateids => 1,
        templateid => 1,
    };
}

sub _prefix {
    my (undef, $suffix) = @_;
    if ($suffix) {
        return 'application'.$suffix;
    } else {
        return 'application';
    }
}

sub _extension {
    return (output => 'extend');
}

sub name {
    my $self = shift;
    return $self->data->{name} || '???';
}

sub _fetch_items {
    my $self = shift;
    my $items = $self->{root}->fetch('Item', params => { applicationids => [ $self->id ] });
    return $items;
}

sub _fetch_host {
    my $self = shift;
    my $host = $self->{root}->fetch_single('Host', params => { hostids => [ $self->data->{hostid} ] });
    return $host;
}

before 'update' => sub {
    # you can create an Application with a hostid, but you can never
    # update it
    my ($self) = @_;
    delete $self->data->{hostid};
};

1;
__END__