File Coverage

blib/lib/Zabbix/Check/Redis.pm

Criterion	Covered	Total	%
statement	19	74	25.6
branch	0	28	0.0
condition	0	6	0.0
subroutine	6	13	46.1
pod	0	2	0.0
total	25	123	20.3

package Zabbix::Check::Redis;
=head1 NAME

Zabbix::Check::Redis - Zabbix check for Redis service

=head1 VERSION

version 1.11

=head1 SYNOPSIS

Zabbix check for Redis service

=cut
use strict;
use warnings;
use v5.10.1;
use Lazy::Utils;

use Zabbix::Check;


BEGIN
{
	require Exporter;
	our $VERSION     = '1.11';
	our @ISA         = qw(Exporter);
	our @EXPORT      = qw(_installed _discovery _running _info);
	our @EXPORT_OK   = qw();
}


our ($redis_server) = whereis('redis-server');
our ($redis_cli) = whereis('redis-cli');


sub bind_to_redis_cli_args
{
	my ($bind) = @_;
	return "" unless defined($bind);
	if ($bind =~ /^([^:]*):(\d*)$/)
	{
		my ($host, $port);
		$host = "127.0.0.1";
		$host = shellmeta($1, 1) if $1 ne "";
		$port = "6379";
		$port = shellmeta($2, 1) if $2 ne "";
		return "-h $host -p $port";
	}
	$bind = shellmeta($bind, 1);
	return "-s $bind";
}

sub get_info
{
	return unless $redis_cli;
	my ($bind) = @_;
	my $redis_cli_args = bind_to_redis_cli_args($bind);
	my $result = file_cache("all", 30, sub
	{
		my $result = { 'epoch' => time() };
		my $topic;
		for (`$redis_cli $redis_cli_args info 2>/dev/null`)
		{
			chomp;
			if (/^#(.*)/)
			{
				$topic = trim($1);
				next;
			}
			my ($key, $val) = split(":", $_, 2);
			next unless defined($topic) and defined($key) and defined($val);
			$key = "$topic:".trim($key);
			$val = trim($val);
			$result->{$key} = $val;
		}
		return $result;
	});
	return $result;
}

sub _installed
{
	my $result = $redis_server? 1: 0;
	print $result;
	return $result;
}

sub _discovery
{
	my @items;
	for (`ps -C redis-server -o pid,cmd 2>/dev/null`)
	{
		chomp;
		if (/^(\d*)\s+\Q$redis_server\E\ (\S+)/)
		{
			push @items, { bind => $2 };
		}
	}
	return print_discovery(@items);
}

sub _running
{
	my ($bind) = @_;
	my $result = 2;
	if ($redis_server)
	{
		my $cmd = $redis_server;
		$cmd .= " $bind" if defined($bind);
		$cmd = shellmeta($cmd);
		system "pgrep -f \"$cmd\" >/dev/null 2>&1";
		$result = ($? == 0)? 1: 0;
	}
	print $result;
	return $result;
}

sub _info
{
	my ($key, $bind) = map(zbx_decode($_), @ARGV);
	return "" unless $key;
	my $result = "";
	my $info = get_info($bind);
	$result = $info->{$key} if defined($info->{$key});
	print $result;
	return $result;
}


1;
__END__