File Coverage

blib/lib/XML/XPath/Helper/String.pm

Criterion	Covered	Total	%
statement	56	56	100.0
branch	24	30	80.0
condition			n/a
subroutine	10	10	100.0
pod	3	3	100.0
total	93	99	93.9

package XML::XPath::Helper::String;

use 5.008;
use strict;
use warnings;

use Exporter 'import';

our $VERSION = '1.02';

our @EXPORT_OK = qw(quoted_string one_of_quoted not_one_of_quoted);

our %EXPORT_TAGS = (all => \@EXPORT_OK);

use Carp;



sub quoted_string {
  @_ == 1 or croak("Wrong number of arguments");
  my $arg = shift;
  my $arg_scalar;
  if (ref($arg)) {
    croak("Argument must be a string or a reference to an array") unless ref($arg) eq 'ARRAY';
  } else {
    $arg_scalar = 1;
    $arg = "" if !defined($arg);
    $arg = [$arg];
  }
  my @result;
  foreach my $string (@{$arg}) {
    if (index($string, "'") >= 0) {
      my @array;
      foreach my $substr (grep{length($_)} split(/('+)/, $string)) {
        my $q = substr($substr, 0, 1) eq "'" ? '"' : "'";
        push(@array, "${q}${substr}${q}");
      }
      push(@result, 'concat(' . join(',', @array) . ')');
    } else {
      push(@result, "'$string'");
    }
  }
  return ($arg_scalar ? $result[0] : \@result);
}


sub one_of_quoted {
  @_ > 0 or croak("Too few arguments");
  my ($array, $name) = @_;
  ref($array) eq 'ARRAY' or croak("Argument 1 must be an ARRAY ref");
  if (defined($name)) {
    ref($name) and croak("Argument 2 must be a scalar");
    return "$name=" . join(" or $name=", @{quoted_string($array)});
  } else {
    my $values = quoted_string($array);
    return sub { return "$_[0]=" . join(" or $_[0]=", @{$values}); };
  }
}


sub not_one_of_quoted {
  @_ > 0 or croak("Too few arguments");
  my ($array, $name) = @_;
  ref($array) eq 'ARRAY' or croak("Argument 1 must be an ARRAY ref");
  if (defined($name)) {
    ref($name) and croak("Argument 2 must be a scalar");
    return "$name!=" . join(" and $name!=", @{quoted_string($array)});
  } else {
    my $values = quoted_string($array);
    return sub { return "$_[0]!=" . join(" and $_[0]!=", @{$values}); };
  }
}



1; # End of XML::XPath::Helper::String



__END__