File Coverage

blib/lib/XML/RSS/TimingBotDBI.pm

Criterion	Covered	Total	%
statement	10	95	10.5
branch	1	28	3.5
condition	0	8	0.0
subroutine	4	19	21.0
pod	7	8	87.5
total	22	158	13.9

package XML::RSS::TimingBotDBI;
$VERSION = '2.01';
use      XML::RSS::TimingBot ();
@ISA = ('XML::RSS::TimingBot');
use Carp ();
use strict;

BEGIN { *DEBUG = sub () {0} unless defined &DEBUG }

die "Where's _elem?!!?" unless __PACKAGE__->can('_elem');
#--------------------------------------------------------------------------
# Some accessors:

sub rssagent_dbh              { shift->_elem('rssdbi_dbh'  , @_) }
sub rssagent_table            { shift->_elem('rssdbi_table', @_) }
sub rssagent_url_field        { shift->_elem('rssdbi_url_field', @_) }
sub rssagent_lastmod_field    { shift->_elem('rssdbi_lastmod_field', @_) }
sub rssagent_nextupdate_field { shift->_elem('rssdbi_rssagent_nextupdate_field', @_) }
sub rssagent_etag_field       { shift->_elem('rssdbi_rssagent_etag_field', @_) }

#==========================================================================

sub _rssagent_init {
  my $self = shift;
  $self->SUPER::_rssagent_init(@_);

  # set some sane values
  $self->rssagent_table('rsstibot');
  $self->rssagent_url_field('feedurl');
  $self->rssagent_lastmod_field('lastmod');
  $self->rssagent_nextupdate_field('nextup');
  $self->rssagent_etag_field('etag');
  return;
}

sub _assert_dbh {
  my $dbh = shift->rssagent_dbh;
  return $dbh if $dbh;
  Carp::confess("Set \$feedbot->rssagent_dbh( \$some_dbi_object ) first!");
}

#--------------------------------------------------------------------------


sub datum_from_db {
  my($self, $url, $varname) = @_;

  my $table       = $self->rssagent_table;
  my $furl        = $self->rssagent_url_field;
  my $fieldname =
     $varname eq 'lastmodified' ? $self->rssagent_lastmod_field
   : $varname eq 'nextupdate'   ? $self->rssagent_nextupdate_field
   : $varname eq 'etag'         ? $self->rssagent_etag_field
   : die "I don't know how to turn \"$varname\" into a fieldname!\nAborting";

  my $sql = "select $fieldname from $table where $furl = ?";  #  binary
  DEBUG and print " DB: $sql => $url\n";
  my $dbh = $self->_assert_dbh;
  $dbh->do("lock tables $table read");
  my($val) = $dbh->selectrow_array($sql, undef, $url);
  $dbh->do("unlock tables;");
  return $val;
}

sub commit {
  my $self = shift;
  my $for_db = $self->{'rsstimingbot_for_db'} || return;
  DEBUG > 1 and print " I see ", scalar(keys %$for_db), " url-data in $self to save\n";
  return unless keys %$for_db;

  my $table       = $self->rssagent_table;

  my $dbh = $self->_assert_dbh;
  $self->_make_table_exist($dbh, $table);
  $dbh->do("lock tables $table write");

  $self->_dump_dirty_cache_to_db(
    $for_db, $dbh,
    $self->_make_sql_statements( $dbh, $table )
  );

  $dbh->commit;
  $dbh->do("unlock tables");

  DEBUG > 4 and print "Done committing.\n";
  $self->{'rsstimingbot_for_db'} = {};
  return;
}

#--------------------------------------------------------------------------

sub _dump_dirty_cache_to_db {
  my($self, $hoh, $dbh, $action2statement) = @_;

  my($for_this_url, $value, $retval);
  foreach my $url (sort keys %$hoh) {
    $for_this_url = $hoh->{$url} || next;
    DEBUG > 4 and print " Vars for $url : ", join(' ', sort keys %$for_this_url), "\n";
   Var:
    foreach my $varname (sort keys %$for_this_url) {
      $value = $for_this_url->{$varname};
      $value = '' unless defined $value;
      DEBUG > 5 and print "   Saving $url 's $varname = \"$value\"\n";
      foreach my $action ('update', 'insert') {
        Carp::confess "No handler for $varname?!"
         unless   $action2statement->{$action}{$varname};
        $retval = $action2statement->{$action}{$varname}->execute( $value,$url );
        Carp::confess "Couldn't find a way to $action $varname=$value for $url\nReason: ",
          $dbh->err||"??", "\nAborting"
         unless $retval; # i.e., if it dies
        next Var  unless  $retval == 0;  # i.e., unless it affected no rows
      }
      Carp::confess "Couldn't find a way to update/insert $varname=$value ?!";
    }
  }
  return;
}

#--------------------------------------------------------------------------

sub _make_sql_statements {
  my($self, $dbh, $table) = @_;

  my $furl        = $self->rssagent_url_field;
  my %action2statement;

  my $sql;
  for my $equiv (
   [ 'lastmodified' => $self->rssagent_lastmod_field    ],
   [ 'nextupdate'   => $self->rssagent_nextupdate_field ],
   [ 'etag'         => $self->rssagent_etag_field       ],
  ) {
    for my $way (
     [ 'update' => "update $table set $$equiv[1] = ? where $furl = ?"    ],
     [ 'insert' => "insert into $table ($$equiv[1], $furl) values (?,?)" ],
    ) {
      $sql = $way->[1];
      $action2statement{ $way->[0] }{ $$equiv[0] } = $dbh->prepare( $sql )
       || die "Couldn't prepare an $$way[0] statement for $$equiv[0]: ".($dbh->err||"??");
      DEBUG > 6 and print "# $$equiv[0] updater: $sql\n";
    }
  }
  return \%action2statement;
}

#--------------------------------------------------------------------------

sub _make_table_exist {
  my($self, $dbh, $table) = @_ ;

  return 1 if $self->{'rssagent_dbh_exists'}{$table};

  my $furl        = $self->rssagent_url_field;
  my $flastmod    = $self->rssagent_lastmod_field;
  my $fnextupdate = $self->rssagent_nextupdate_field;
  my $fetag       = $self->rssagent_etag_field;

  foreach my $method (
    '_create_table_if_not_exists', '_just_create_table',
  ) {
    next unless $self->$method(
      $dbh, $table, $furl, $fnextupdate, $flastmod, $fetag
    );
    DEBUG > 7 and print "  DB: $method worked.\n";
    $self->{'rssagent_dbh_exists'}{$table} = 1;
    return;
  }
  Carp::confess "I don't know how to make table $table for $dbh and $self!\nAborting";
}

sub _create_table_if_not_exists {
  my($self, $dbh, $table, $furl, $fnextupdate, $flastmod, $fetag) = @_ ;
  return 1 if $dbh->do(qq<
      create table if not exists
      $table (
       $furl varchar(255) not null primary key,
       $fnextupdate int(11),
       $flastmod varchar(40),
       $fetag varchar(250)
      )
  >);
  return 0;
}

sub _just_create_table { # keep it real simple...
  my($self, $dbh, $table, $furl, $fnextupdate, $flastmod, $fetag) = @_ ;
  return 1 if $dbh->do(qq<
      create table
      $table (
       $furl varchar(255) not null primary key,
       $fnextupdate int(11),
       $flastmod varchar(40),
       $fetag varchar(250)
      )
  >);
  return 0;
}

#--------------------------------------------------------------------------

1;
__END__