File Coverage

blib/lib/XML/Compile/SOAP/Daemon/Dancer2.pm

Criterion	Covered	Total	%
statement	21	23	91.3
branch			n/a
condition			n/a
subroutine	8	8	100.0
pod			n/a
total	29	31	93.5

package XML::Compile::SOAP::Daemon::Dancer2;
use strict;
use warnings;
use 5.008_005;
our $VERSION = '0.07';
use Dancer2::Plugin;
use Dancer2::FileUtils 'path';
use Class::Load qw(try_load_class);
use Carp;

use XML::Compile::SOAP::Daemon::Dancer2::Handler;
use XML::Compile::WSDL11;
use XML::Compile::SOAP11;
use XML::Compile::SOAP12;

sub get_implementation {
    my ( $class_name, $dsl ) = @_;
    my ($ok, $error) = try_load_class($class_name);
    if (! $ok) {
        confess "Cannot load implementation class $class_name: $error";
    }

    my $implementation = $class_name->new( dsl => $dsl );

    die "Implementation class needs to do the role XML::Compile::SOAP::Daemon::Dancer2::Role::Implementation"
        unless $implementation->DOES('XML::Compile::SOAP::Daemon::Dancer2::Role::Implementation');

    return $implementation;
}

register 'wsdl_endpoint' => sub {
    my ($dsl, $path, $options) = @_;

    my $settings = plugin_setting;
    my $wsdl_path = path( $dsl->setting('appdir'), $settings->{wsdl_path}//"wsdl" );
    my $xsd_path = path( $dsl->setting('appdir'), $settings->{xsd_path}//"wsdl" );

    for my $key ( qw(wsdl) ) {
        confess "$key option mandatory when calling wsdl_endpoint" unless exists $options->{$key};
    }

    my $wsdl_file = path( $wsdl_path, $options->{wsdl} );
    unless( -f $wsdl_file ) {
        confess "wsdl file not found ($wsdl_file)";
    }

    my $wsdl = XML::Compile::WSDL11->new( $wsdl_file  );

    if( exists $options->{xsd} ) {
        if( ref $options->{xsd} eq 'ARRAY' ) {
            for my $file ( @{$options->{xsd}} ) {
                my $xsd_file = path( $xsd_path, $file );
                $wsdl->importDefinitions( $xsd_file );
            }
        } else {
            confess 'xsd must be an array ref of xsd files';
        }
    }

    my $operations = {};
    if( exists $options->{operations} ) {
        confess "operation should be a hasref of operation => sub {}" unless ref $options->{operations} eq "HASH";
        $operations = $options->{operations};
    }
    if( exists $options->{implementation_class} ) {
        #class provided for inplementation
        #try to load the class
        my $implementation = get_implementation( $options->{implementation_class}, $dsl );

        for my $operation ( $wsdl->operations() ) {
            #$dsl->error( $operation->action );
            if( my $call = $implementation->can("soapaction_".$operation->action) ) {
                $operations->{$operation->action} = sub { $implementation->$call( @_ ) };
            }
        }
    }

    my $daemon = XML::Compile::SOAP::Daemon::Dancer2::Handler->new();

    $daemon->operationsFromWSDL(
        $wsdl,
        callbacks => $operations,
    );

    $dsl->app->add_route(
        method  => 'get',
        regexp  => $path,
        code    => sub {
            my $params = $dsl->params;

            if( exists $params->{wsdl} ) {
                $dsl->content_type( 'application/wsdl+xml' );
                $dsl->send_file( $wsdl_file , system_path => 1 );
            }
        }
    );

    $dsl->app->add_route(
        method  => 'post',
        regexp  => $path,
        code    => sub {
            $daemon->handle( $dsl );
        }
    );
};

register_plugin;
1;
__END__