File Coverage

blib/lib/Wurm/Grub/REST.pm

Criterion	Covered	Total	%
statement	61	80	76.2
branch	32	60	53.3
condition	2	6	33.3
subroutine	14	16	87.5
pod	6	6	100.0
total	115	168	68.4

package Wurm::Grub::REST;

use strict;
use warnings;
use parent qw(Wurm::let);

use Wurm;

sub new {
  my ($self, $map) = @_;

  $map //= {
    'text/html'        => 'html',
    'application/json' => 'json',
    'text/xml'         => 'xml',
    'application/xml'  => 'xml',
  };

  die "invalid type map" unless 'HASH' eq ref $map;

  $self->SUPER::new->gate(sub {
    my $meal = shift;

    for my $accept (split ',', $meal->{env}{HTTP_ACCEPT}) {
      my $node = $map->{$accept};
      $meal->{vent}{$node} = 1
        if defined $node;
    }

    $meal->{grit}{id} = Wurm::bend($meal);
    return;
  });
}

sub get {
  my ($self, $one, $all) = @_;

  die "invalid handler" unless 'CODE' eq ref $one;
  die "invalid handler" unless 'CODE' eq ref $all;

  $self->SUPER::get(sub {
    my $meal = shift;
    my $cast = defined $meal->{grit}{id}
      ? $one->($meal)
      : $all->($meal)
    ;
    return defined $cast ? $cast : Wurm::_404();
  });
}

sub post {
  my ($self, $post) = @_;

  die "invalid handler" unless 'CODE' eq ref $post;

  $self->SUPER::post(sub {
    my $meal = shift;

    return Wurm::_400()
      if defined $meal->{grit}{id};

    my $cast = $post->($meal);
    return $cast
      if defined $cast;

    return Wurm::_400()
      unless defined $meal->{grit}{id};

    my $uri = $meal->{seen} // '';
    $uri .= '/' if '/' ne substr($uri, length($uri) - 1, 1);
    $uri .= $meal->{grit}{id};

    return Wurm::_201($uri);
  });
}

sub put {
  my ($self, $new, $old) = @_;

  die "invalid handler" unless 'CODE' eq ref $new;
  die "invalid handler" unless 'CODE' eq ref $old;

  $self->SUPER::put(sub {
    my $meal = shift;
    my $flag = defined $meal->{grit}{id};
    my $cast = $flag
      ? $old->($meal)
      : $new->($meal)
    ;
    return $cast
      if defined $cast;

    return Wurm::_400()
      unless defined $meal->{grit}{id};

    my $uri = $meal->{seen} // '';
    $uri .= '/' if '/' ne substr($uri, length($uri) - 1, 1);
    $uri .= $meal->{grit}{id};

    return $flag ? Wurm::_302($uri) : Wurm::_201($uri);
  });
}

sub patch {
  my ($self, $one, $all) = @_;

  die "invalid handler" unless 'CODE' eq ref $one;

  $self->SUPER::patch(sub {
    my $meal = shift;

    my $cast;
    if(defined $meal->{grit}{id}) {
      $cast = $one->($meal);
      return Wurm::_400() unless defined $meal->{grit}{id};
      return Wurm::_404() unless defined $cast;
    }
    else {
      return Wurm::_404() unless defined $all;
      $cast = $all->($meal);
      return Wurm::_400() unless defined $cast;
    }
    return $cast;
  });
}

sub delete {
  my ($self, $one, $all) = @_;

  die "invalid handler" unless 'CODE' eq ref $one;

  return $self->SUPER::delete(sub {
    my $meal = shift;

    my $cast;
    if(defined $meal->{grit}{id}) {
      $cast = $one->($meal);
      return Wurm::_400() unless defined $meal->{grit}{id};
      return Wurm::_404() unless defined $cast;
    }
    else {
      return Wurm::_404() unless defined $all;
      $cast = $all->($meal);
      return Wurm::_400() unless defined $cast;
    }
    return $cast;
  });
}

'.oOo.' # in wurm i trust
__END__