File Coverage

blib/lib/Wrangler.pm

Criterion	Covered	Total	%
statement	19	21	90.4
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	26	28	92.8

package Wrangler;

use strict;
use warnings;

use Wrangler::PubSub;
use Wrangler::Config;
use Wrangler::PluginManager;
use Wrangler::FileSystem::Layers;
use Wrangler::Wx::App;

our $VERSION = 2.14;
our $log = 0;
our $wishlist;

sub new {
	my $class = shift;
	my $self = bless {
		appname	=> 'Wrangler',
		version	=> $VERSION,
		@_
	}, $class;

	## load config
	Wrangler::Config::read();

	## simple CLI switch parsing
	if(@ARGV){
		for(@ARGV){
			if($_ eq '--debug'){
				$self->{debug} = 1;
				$log = 1; # $log is non-OO for efficiency
			}elsif($_ =~ /^\/|^\\/){
				$Wrangler::Config::env{CLI_ChangeDirectory} = $_;
			}
		}
	}

	## establish PluginManager
	Wrangler::PluginManager::load_plugins($self);

	## establish our virtual file-system
	$self->{fs} = Wrangler::FileSystem::Layers->new();

	Wrangler::PubSub::subscribe('file.activated', \&OnActivated,__PACKAGE__);
	Wrangler::PubSub::subscribe('main.menubar.toggle', sub {
		$self->{main}->OnToggleMenuBar($_[0]);
	},__PACKAGE__);
	Wrangler::PubSub::subscribe('main.navbar.toggle', sub {
		$self->{main}->OnToggleNavbar($_[0]);
	},__PACKAGE__);
	Wrangler::PubSub::subscribe('main.sidebar.toggle', sub {
		$self->{main}->OnToggleSidebar($_[0]);
	},__PACKAGE__);
	Wrangler::PubSub::subscribe('main.statusbar.toggle', sub {
		$self->{main}->OnToggleStatusBar($_[0]);
	},__PACKAGE__);
	Wrangler::PubSub::subscribe('main.formeditor.recreate', sub {
		$self->{main}->OnReCreateFormEditor($_[0]);
	},__PACKAGE__);
	Wrangler::PubSub::publish('status.update', "Init complete");

	return $self;
}

sub config {
	Wrangler::Config::config(@_);
}

sub debug {
	print $_[0] . "\n" if $log;
}

sub wishlist {
	# use Data::Dumper;
	# print 'Wrangler::wishlist:'.Dumper($wishlist);
	return [ keys %$wishlist ];
}

sub run {
	my $self = shift;

	## create the Wx App and its main window
	my $app = Wrangler::Wx::App->new();	# Create the application object
	$self->{main} = $app->create($self);
	$app->MainLoop;				# Start event processing
}

sub OnActivated {
	Wrangler::debug("Main:: received event 'file.activated': @_");
	my ($path,$richlist_item) = @_;

	if($richlist_item->{'MIME::mediaType'}){
		my $viewers = $Wrangler::Config::settings{'openwith'};
		if( $viewers->{ $richlist_item->{'MIME::mediaType'} . '/*' } ){
			Wrangler::debug(" mediaType ".$richlist_item->{'MIME::mediaType'} ." has association ". $viewers->{ $richlist_item->{'MIME::mediaType'} . '/*' } .", appending path $richlist_item->{'Filesystem::Path'}) ");
			my $pid = ForkAndExec($viewers->{ $richlist_item->{'MIME::mediaType'} . '/*' }, $richlist_item->{'Filesystem::Path'} );
			Wrangler::PubSub::publish('status.update',"Launched external viewer with pid $pid");
			return;
		}
	}

	Wrangler::debug("No viewer associated or MIME::mediaType unknown. returning. ");
}

sub ForkAndExec {
	my @commands = @_;

	my $pid = fork();

	print STDERR "unable to fork: $!" unless defined($pid);
	return undef unless defined($pid);

	# contains no pid when we're in the forked child
	if(!$pid){
		exec(@commands);
		die "unable to exec: $!";
	}

	return $pid if $pid;
}

sub DESTROY {
	Wrangler::debug("Wrangler::DESTROY");

	## store config if it has changed
	Wrangler::Config::write()
}

1;

__END__