File Coverage

blib/lib/WordNet/Similarity/lin.pm

Criterion	Covered	Total	%
statement	4	6	66.6
branch			n/a
condition			n/a
subroutine	2	2	100.0
pod			n/a
total	6	8	75.0

# WordNet::Similarity::lin.pm version 2.04
# (Last updated $Id: lin.pm,v 1.22 2008/03/27 06:21:17 sidz1979 Exp $)
#
# Semantic Similarity Measure package implementing the measure
# described by Lin (1998).
#
# Copyright (c) 2005,
#
# Ted Pedersen, University of Minnesota Duluth
# tpederse at d.umn.edu
#
# Siddharth Patwardhan, University of Utah, Salt Lake City
# sidd at cs.utah.edu
#
# Jason Michelizzi, Univeristy of Minnesota Duluth
# mich0212 at d.umn.edu
#
# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.
#
# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.
#
# You should have received a copy of the GNU General Public License
# along with this program; if not, write to
#
# The Free Software Foundation, Inc.,
# 59 Temple Place - Suite 330,
# Boston, MA  02111-1307, USA.
#
# ------------------------------------------------------------------

package WordNet::Similarity::lin;

=head1 NAME

WordNet::Similarity::lin - Perl module for computing semantic relatedness
of word senses using the information content based measure described by
Lin (1998).

=head1 SYNOPSIS

  use WordNet::Similarity::lin;

  use WordNet::QueryData;

  my $wn = WordNet::QueryData->new();

  my $mymeasure = WordNet::Similarity::lin->new($wn);

  my $value = $mymeasure->getRelatedness("car#n#1", "bus#n#2");

  ($error, $errorString) = $mymeasure->getError();

  die "$errorString\n" if($error);

  print "car (sense 1) <-> bus (sense 2) = $value\n";

=head1 DESCRIPTION

Lin (1998) describes a method to compute the semantic relatedness of word
senses using the information content of the concepts in WordNet and the
'Similarity Theorem' (also described in the paper). This module implements
this measure of semantic relatedness of concepts.

=over

=cut

use strict;
use WordNet::Similarity::ICFinder;

our @ISA = qw(WordNet::Similarity::ICFinder);

our $VERSION = '2.04';

=item $lin->getRelatedness ($synset1, $synset1)

Computes the relatedness of two word senses using an information content
scheme.  The relatedness is equal to twice the information content of the
LCS divided by the sum of the information content of each input synset.

Parameters: two word senses in "word#pos#sense" format.

Returns: Unless a problem occurs, the return value is the relatedness
score.  If no path exists between
the two word senses, then a large negative number is returned.  If an
error occurs, then the error level is set to non-zero and an error string
is created (see the description of getError()).  Note: the error level
will also be set to 1 and an error string will be created if no path
exists between the words.

=cut

sub getRelatedness
{
  my $self = shift;
  my $wps1 = shift;
  my $wps2 = shift;
  my $wn = $self->{'wn'};
  my $class = ref $self || $self;

  # Check the existence of the WordNet::QueryData object.
  unless ($wn) {
    $self->{errorString} .= "\nError (${class}::getRelatedness()) - ";
    $self->{errorString} .= "A WordNet::QueryData object is required.";
    $self->{error} = 2;
    return undef;
  }

  # Initialize traces.
  $self->{traceString} = "";

  # JM 1-21-04
  # moved input validation code to WordNet::Similarity::parseInput()
  my $ret = $self->parseWps ($wps1, $wps2);
  ref $ret or return $ret;
  my ($word1, $pos1, $sense1, $offset1, $word2, $pos2, $sense2, $offset2)
    = @{$ret};

  my $synset1 = "$word1#$pos1#$sense1";
  my $synset2 = "$word2#$pos2#$sense2";

  # Now check if the similarity value for these two synsets is in
  # fact in the cache... if so return the cached value.
  my $relatedness =
    $self->{doCache} ? $self->fetchFromCache ($synset1, $synset2) : undef;
  defined $relatedness and return $relatedness;

  # Now get down to really finding the relatedness of these two.
  my @LCSs = $self->getLCSbyIC ($synset1, $synset2, $pos1, 'wps');

  my $ref = shift @LCSs;

  unless (defined $ref) {
    return $self->UNRELATED;
  }

  my ($lcs, $lcsic) = @{$ref};

  my $ic1 = $self->IC ($offset1, $pos1);
  my $ic2 = $self->IC ($offset2, $pos2);
  my $score = ($ic1 && $ic2) ? ((2 * $lcsic) / ($ic1 + $ic2)) : 0;

  # what does this do?
  $score = ($score == -1) ? 0 : $score;

  if ($self->{trace}) {
    $self->{traceString} .= "Concept1: $synset1 (IC=";
    $self->{traceString} .= sprintf ("%.6f", $ic1);
    $self->{traceString} .= ")\n";
    $self->{traceString} .= "Concept2: $synset2 (IC=";
    $self->{traceString} .= sprintf ("%.6f", $ic2);
    $self->{traceString} .= ")\n";
  }

  $self->{doCache} and $self->storeToCache ($wps1, $wps2, $score);
  return $score;
}

# JM 1-16-04
# moved subroutine _getLeastCommonSubsumers to ICFinder.pm

1;

__END__