File Coverage

blib/lib/Win32/SqlServer/DTS/Credential.pm

Criterion	Covered	Total	%
statement	25	29	86.2
branch	3	6	50.0
condition	1	3	33.3
subroutine	6	6	100.0
pod	2	2	100.0
total	37	46	80.4

package Win32::SqlServer::DTS::Credential;

=head1 NAME

Win32::SqlServer::DTS::Credential - credentials to authenticate against a MS SQL Server 2000

=head1 SYNOPSIS

    use Win32::SqlServer::DTS::Credential;

    # regular authentication method
    my $credential = Win32::SqlServer::DTS::Credential->new(
        {
            server                 => 'somedatabase',
            user                   => 'user',
            password               => 'password',
            use_trusted_connection => 0
        }
    );

    #trusted authentication mode

    my $credential2 =
      Win32::SqlServer::DTS::Credential->new(
        { server => 'somedatabase', use_trusted_connection => 1 } );

=head1 DESCRIPTION

C implements the authentication scheme expected by MS SQL Server connection depending
on the mode that will be used (regular authentication or trusted connection).

This class was created to be able to invoke the DTS Application C (and others) method in a polymorphic
way, since these methods expect a lot of parameters given in the correct order (some parameters are even unused, but
one must inform them anyway).

One should not need to use this class directly: it is used by the L module and, if
you're using this class there is nothing to worry about authentication.

=head2 EXPORT

Nothing.

=cut

use strict;
use warnings;
use Carp qw(confess);
use Hash::Util qw(lock_keys);

=head2 METHODS

C does not inherients from any superclass. This means that the methods available in L are
not available.

=head3 new

This method creates a new C object. A hash reference must be passed as a parameter
(see L for examples).

Depending on the authentication method, C and C are necessary or not. The Trusted Connection does
not need such values, but the C method will abort with an error if you pass no keys with the necessary values.

A C object will have the following attributes:

=over

=item *
server

=item *
user

=item *
password

=item *
auth_code

=back

C is defined by the DTS Application object documentation to be defined as explained below:

=over

=item *
Constant DTSSQLStgFlag_Default  = 0

=item *
Constant DTSSQLStgFlag_UseTrustedConnection = 256

=back

=cut

sub new {

    my $class = shift;
    my $self  = shift;

    confess 'expects an hash refence as a parameter'
      unless ( ref($self) eq 'HASH' );

    unless ( $self->{use_trusted_connection} ) {

        unless (( exists( $self->{user} ) )
            and ( exists( $self->{password} ) ) )
        {

            confess
"Username and password cannot be NULL if trusted connection is not in use\n";

        }
        $self->{auth_code} = 0;

        #creates the missing keys to avoid issues when invoking to_list method
    }
    else {

        $self->{user}      = '';
        $self->{password}  = '';
        $self->{auth_code} = 256;

    }

    delete $self->{use_trusted_connection};

    bless $self, $class;
    lock_keys( %{$self} );
    return $self;

}

=head3 to_list

Returns all attributes of the object in a ordered list. This will be used during method invoking to authenticate
the request against the MS SQL Server. The list is returned in this order:

=over

=item 1
server

=item 2
user

=item 3
password

=item 4
auth_code

=back

=cut

sub to_list {

    my $self = shift;
    return $self->{server}, $self->{user}, $self->{password},
      $self->{auth_code};

}

1;

__END__