File Coverage

blib/lib/WebService/Strike.pm

Criterion	Covered	Total	%
statement	55	56	98.2
branch	12	14	85.7
condition			n/a
subroutine	15	15	100.0
pod	3	3	100.0
total	85	88	96.5

package WebService::Strike;

use 5.014000;
use strict;
use warnings;
use parent qw/Exporter/;

our @EXPORT    = qw/strike strike_search strike_imdb/; ## no critic (ProhibitAutomaticExportation)
our @EXPORT_OK = (@EXPORT, 'strike_query');
our $VERSION = '0.004002';
our $BASE_URL = 'https://getstrike.net/api/v2';

use JSON::MaybeXS qw/decode_json/;
use HTTP::Tiny;
use Sort::ByExample qw/sbe/;
use WebService::Strike::Torrent;

sub _ht { HTTP::Tiny->new(agent => "WebService-Strike/$VERSION", verify_SSL => 1) }

sub _query {
	my ($url) = @_;

	my $ht = _ht;
	my $response = $ht->get($url);
	die $response unless $response->{success}; ## no critic (RequireCarping)
	$response = decode_json $response->{content};

	map { WebService::Strike::Torrent->new($_) } @{$response->{torrents}};
}

sub strike_query {
	my (@hashes) = @_;
	if (@hashes > 50) {
		return strike_query (@hashes[0 .. 49]), strike_query (@hashes[50 .. $#hashes]);
	}
	my $url = "$BASE_URL/torrents/info/?hashes=" . join ',', map { uc } @hashes;

	my $sorter = sbe(\@hashes, {xform => sub { $_[0]->hash }});
	my @torrents = $sorter->(_query $url);
	wantarray ? @torrents : $torrents[0]
}

sub strike_search {
	my ($query, $full, %args) = @_;
	$args{phrase} = $query;
	my $url = "$BASE_URL/torrents/search/?" . HTTP::Tiny->www_form_urlencode(\%args);

	my @torrents = _query $url;
	@torrents = $torrents[0] unless wantarray;
	@torrents = strike_query map { $_->hash } @torrents if $full;
	wantarray ? @torrents : $torrents[0]
}

sub strike_imdb {
	my ($id) = @_;
	my $url = "$BASE_URL/media/imdb/?imdbid=$id";
	my $response = _ht->get($url);
	return unless $response->{success};
	decode_json $response->{content}
}

BEGIN { *strike = \&strike_query }

1;
__END__