File Coverage

blib/lib/WebService/Riya.pm

Criterion	Covered	Total	%
statement	19	21	90.4
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	26	28	92.8

package WebService::Riya;

use strict;
use warnings;
use base qw(Class::Accessor::Fast);

use HTTP::Request::Common;
use LWP::UserAgent;
use URI;
use XML::LibXML;

our $VERSION = '0.01';

my $API_ROOT = 'http://www.riya.com/rest';

__PACKAGE__->mk_accessors(qw/user_name password api_key errstr status debug/);

sub new {
    my($class, %opt) = @_;
    my $self = bless {
        user_name => $opt{user_name},
        password  => $opt{password},
        api_key   => $opt{api_key},
    }, $class;
    $self->{ua} = LWP::UserAgent->new;
    return $self;
}

sub get_auth_token {
    my $self = shift;

    return $self->{token} if $self->{token};

    my $uri = URI->new($API_ROOT);
    $uri->query_form(
        user_name => $self->user_name,
        password  => $self->password,
        api_key   => $self->api_key,
        method    => 'riya.auth.GetToken',
    );
    my $response = $self->{ua}->get($uri->as_string);

    my $xml = XML::LibXML->new();
    my $doc = $xml->parse_string($response->content);

    $self->{token} = $doc->findvalue("//*[local-name()='token']");

    $self->errstr($doc->findvalue("//*[local-name()='error']/\@code"))
        unless $self->{token};

    return $self->{token};
}

sub call_method {
    my($self, $method, $opt) = @_;

    my $uri = URI->new($API_ROOT);
    my $req_param;
    $opt->{user_name}  = $self->user_name;
    $opt->{password}   = $self->password;
    $opt->{api_key}    = $self->api_key;
    $opt->{auth_token} = $self->get_auth_token();
    $opt->{method}     = $method;
    if (lc $method eq 'riya.photos.upload.uploadphoto') {
        $req_param = POST($API_ROOT, Content_Type => 'form-data', Content => [%$opt]);
    } else {
        $uri->query_form($opt);
        $req_param = GET($uri->as_string);
    }
    my $response = $self->{ua}->request($req_param);

    warn $uri->as_string if $self->debug;

    return '' unless $response->content;

    my $xml = XML::LibXML->new();
    my $doc = $xml->parse_string($response->content);

    $self->errstr($doc->findvalue("//*[local-name()='error']/\@code"));
    $self->status($self->errstr() ? 0 : 1);

    return $response->content;
}

1;
__END__