File Coverage

blib/lib/WebService/PhotoZou.pm

Criterion	Covered	Total	%
statement	19	21	90.4
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	26	28	92.8

package WebService::PhotoZou;
use strict;
use warnings;
use base qw(Class::Accessor::Fast);

use Carp;
use HTTP::Request::Common;
use LWP::UserAgent;
use XML::Simple;

our $VERSION = '0.01';

my %API_ROOT = (
    jp  => 'http://api.photozou.jp/rest/',
    com => 'http://api.photozou.com/rest/',
);

__PACKAGE__->mk_accessors(qw/username password errors/);

sub new {
    my ($class, %opt) = @_;
    my $site = $opt{site} || 'jp';
    my $api_root = $API_ROOT{$site};
    croak("unknown site $site") unless $api_root;
    my ($host) = $api_root =~ m!^http://(.*?)/!;
    my $self = bless {
        username => $opt{username} || '',
        password => $opt{password} || '',
        api_root => $api_root,
        host     => $host,
    }, $class;
    $self;
}

sub ua {
    my $self = shift;
    if (@_) {
        $self->{ua} = shift;
    } else {
        $self->{ua} and return $self->{ua};
        $self->{ua} = LWP::UserAgent->new;
        $self->{ua}->agent(__PACKAGE__."/$VERSION");
    }
    $self->{ua};
}

sub _request {
    my ($self, $url, %param) = @_;
    $self->ua->credentials("$self->{host}:80", 'photo', $self->username, $self->password);
    my $req = (grep { ref $_ eq 'ARRAY' } values %param)
        ? POST($self->{api_root}.$url, Content_Type => 'form-data', Content => [%param])
        : POST($self->{api_root}.$url, [%param]);
    my $res = $self->ua->request($req);
    croak("request failed.\n".$res->status_line) if $res->is_error;
    $res->content;
}

sub _to_result {
    my ($self, $xml, %opt) = @_;
    if (exists $opt{ForceArray}) {
        push @{$opt{ForceArray}}, 'err';
    } else {
        $opt{ForceArray} = ['err'];
    }
    my $result = XML::Simple::XMLin($xml, %opt);
    if ($result->{stat} eq 'fail') {
        $self->{errors} = $result->{err};
        return;
    }
    $result;
}

sub nop {
    my $self = shift;
    my $content = $self->_request('nop');
    my $res = $self->_to_result($content) or return;
    $res->{stat};
}

sub photo_add {
    my ($self, %param) = @_;
    croak('paramater photo is required') unless exists $param{photo};
    croak('paramater album_id is required') unless exists $param{album_id};
    $param{photo} = [$param{photo}];
    my $content = $self->_request('photo_add', %param);
    my $res = $self->_to_result($content) or return;
    $res->{photo_id};
}

sub photo_add_album {
    my ($self, %param) = @_;
    croak('paramater name is required') unless exists $param{name};
    my $content = $self->_request('photo_add_album', %param);
    my $res = $self->_to_result($content) or return;
    $res->{album_id};
}

sub photo_album {
    my $self = shift;
    my $content = $self->_request('photo_album');
    my $res = $self->_to_result($content,
        KeyAttr    => 'album',
        ForceArray => ['album'],
    ) or return;
    $res->{info}->{album} || [];
}

sub search_public {
    my ($self, %param) = @_;
    my $content = $self->_request('search_public', %param);
    my $res = $self->_to_result($content, ForceArray => ['photo']) or return;
    $res->{info}->{photo} || [];
}

sub user_group {
    my $self = shift;
    my $content = $self->_request('user_group');
    my $res = $self->_to_result($content,
        keyAttr    => 'user_group',
        ForceArray => ['user_group'],
    ) or return;
    $res->{info}->{user_group} || [];
}

sub errormsg {
    my $self = shift;
    my $msg;
    for my $error (@{$self->errors}) {
        $msg .= "$error->{code}: $error->{msg}\n";
    }
    $msg;
}

1;
__END__