File Coverage

blib/lib/WebService/Livedoor/Weather.pm

Criterion	Covered	Total	%
statement	19	21	90.4
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	26	28	92.8

package WebService::Livedoor::Weather;

use strict;
use warnings;
use utf8;
use Carp;
use Encode;
use URI::Fetch;
use XML::Simple;
use JSON 2;
our $VERSION = '0.10';

use constant BASE_URI        => $ENV{LDWEATHER_BASE_URI} || 'http://weather.livedoor.com';
use constant ENDPOINT_URI    => $ENV{LDWEATHER_ENDPOINT_URI} || BASE_URI. '/forecast/webservice/json/v1';
use constant FORECASTMAP_URI => $ENV{LDWEATHER_FORECASTMAP_URI} || BASE_URI. '/forecast/rss/primary_area.xml';

sub new {
    my ( $class, %args ) = @_;
    $args{fetch} ||= {};
    $args{fetch} = {
        %{$args{fetch}},
        UserAgent => LWP::UserAgent->new( agent => __PACKAGE__.'/'.$VERSION )
    };
    bless \%args,$class;
}

sub get {
    my ($self, $city) = @_;
    croak('city is required') unless $city;
    my $cityid = $self->__get_cityid($city);

    my $res = URI::Fetch->fetch(ENDPOINT_URI. "?city=$cityid", %{$self->{fetch}});
    croak("Cannot get weather information : " . URI::Fetch->errstr) unless $res;

    return $self->__parse_forecast($res->content);
}

sub __parse_forecast {
    my ($self, $json) = @_;
    my $ref;
    eval{$ref = decode_json($json)};
    croak('Oops! failed reading weather information : ' . $@) if $@;

    ### temperature fixing for null case
    for ( @{$ref->{forecasts}} ) {
        ref $_->{temperature}{max}{celsius} and $_->{temperature}{max}{celsius} = undef;
        ref $_->{temperature}{min}{celsius} and $_->{temperature}{min}{celsius} = undef;
        ref $_->{temperature}{max}{fahrenheit} and $_->{temperature}{max}{fahrenheit} = undef;
        ref $_->{temperature}{min}{fahrenheit} and $_->{temperature}{min}{fahrenheit} = undef;
    }

    return $ref;
}

sub __get_cityid {
    my ($self,$city) = @_;
    $city =~ /^\d+$/ ? $city : $self->__forecastmap->{$city} or croak('Invalid city name. cannot find city id with '. $city);
}

sub __forecastmap {
    my $self = shift;
    unless ($self->{forecastmap}) {
        my $res = URI::Fetch->fetch(FORECASTMAP_URI, %{$self->{fetch}});
        croak("Couldn't get forecastmap: " . URI::Fetch->errstr) unless $res;
        $self->{forecastmap} = $self->__parse_forecastmap($res->content);
    }
    return $self->{forecastmap};
}

sub __parse_forecastmap {
    my ($self, $str) = @_;

    my $ref = eval {
        local $XML::Simple::PREFERRED_PARSER = 'XML::Parser';
        XMLin($str, ForceArray => [qw[pref area city]]);
    };
    if ($@) {
        local $Carp::CarpLevel = 1;
        croak('Oops! failed reading forecastmap: '. $@);
    }
    my %forecastmap;
    foreach my $pref ( @{$ref->{channel}{'ldWeather:source'}{pref}} ){
        $forecastmap{$pref->{city}{$_}{title}} = $_ for keys %{$pref->{city}};
    }
    return \%forecastmap;
}

1;
__END__