File Coverage

blib/lib/WebService/KvKAPI/Roles/OpenAPI.pm

Criterion	Covered	Total	%
statement	32	34	94.1
branch	8	12	66.6
condition			n/a
subroutine	16	18	88.8
pod	10	10	100.0
total	66	74	89.1

use utf8;
package WebService::KvKAPI::Roles::OpenAPI;
our $VERSION = '0.103';
# ABSTRACT: WebService::KvkAPI::Roles::OpenAPI package needs a propper abstract

use v5.26;
use Object::Pad;

role WebService::KvKAPI::Roles::OpenAPI;
use Carp qw(croak);
use OpenAPI::Client;
use Try::Tiny;

has $api_host :accessor :param = undef;
has $api_key  :param = undef;
has $spoof    :param = 0;
has $client   :accessor;

ADJUST {

    my $base_uri = 'https://api.kvk.nl/api';

    if ($spoof) {
        $base_uri = 'https://api.kvk.nl/test/api';
        # publicly known API key
        $api_key = 'l7xx1f2691f2520d487b902f4e0b57a0b197';
    }

    # work around api-key not being present with the api_call method
    if (!defined $api_key) {
        croak("Please supply an API-key with construction");
    }

    my $definition = sprintf('data://%s/kvkapi.yml', ref $self);
    $client = OpenAPI::Client->new($definition, base_url => $base_uri);
    if ($self->has_api_host) {
        $client->base_url->host($self->api_host);
    }

    $client->ua->on(start => sub ($ua, $tx) {
      $tx->req->headers->header('apikey' => $api_key);
    });
}

method is_spoof {
    return $spoof ? 1 : 0;
}

method has_api_host {
    return defined $api_host ? 1 : 0;
}

method api_call {
    my ($operation, %query) = @_;

    my $tx = try {
        $client->call(
            $operation => \%query,
        );
    }
    catch {
        die("Died calling KvK API with operation '$operation': $_", $/);
    };

    if ($tx->error) {
        # Not found, no result
        return if  $tx->res->code == 404;

        # Any other error
        croak(
            sprintf(
                "Error calling KvK API with operation '%s': '%s' (%s)",
                $operation, $tx->result->body, $tx->error->{message}
            ),
        );
    }

    return $tx->res->json;
}

1;

__END__