File Coverage

blib/lib/WebService/KakakuCom.pm

Criterion	Covered	Total	%
statement	25	27	92.5
branch			n/a
condition			n/a
subroutine	9	9	100.0
pod			n/a
total	34	36	94.4

package WebService::KakakuCom;
use strict;
use warnings;
use base qw/Class::Accessor::Fast Class::Data::Inheritable/;

use URI;
use Carp;
use Readonly;
use LWP::UserAgent;
use Jcode;
use WebService::KakakuCom::Parser;
use Data::Page;

Readonly my $ApiRoot => 'http://api.kakaku.com/Ver1/';
Readonly my $EntriesPerPage => 5;

our $VERSION = 0.05;

__PACKAGE__->mk_accessors(qw/ie/);
__PACKAGE__->mk_classdata($_) for qw/debug/;

sub ua {
    my $self = shift;
    if (@_) {
        $self->{ua} = shift;
    } else {
        $self->{ua} and return $self->{ua};
        $self->{ua} = LWP::UserAgent->new;
        $self->{ua}->agent(join '/', __PACKAGE__, $self->VERSION);
    }
    $self->{ua};
}

sub search {
    my ($self, $keyword, $args) = @_;
    defined $keyword or croak "No keyword was given";
    $args ||= {};

    my $uri = URI->new_abs('ItemSearch.asp', $ApiRoot);
    $uri->query_form(
        Keyword       => Jcode->new($keyword, $self->ie)->sjis,
        CategoryGroup => $args->{CategoryGroup} || 'ALL',
        ResultSet     => $args->{ResultSet} || 'medium',
        SortOrder     => $args->{SortOrder} || '',
        PageNum       => $args->{PageNum} || 1,
    );

    my $res = $self->ua->get($uri);
    croak $res->status_line if $res->is_error;

    my $rs = WebService::KakakuCom::Parser->parse_for_search($res->content);
    $rs->pager(Data::Page->new($rs->NumOfResult, $EntriesPerPage, $args->{PageNum} || 1));

    wantarray ? @$rs : $rs;
}

sub product {
    my ($self, $product_id, $args) = @_;
    defined $product_id or croak "No ProductID was given";
    $args ||= {};

    my $uri = URI->new_abs('ItemInfo.ashx', $ApiRoot);
    $uri->query_form(
        ProductID => $product_id,
        ResultSet => $args->{ResultSet} || 'medium'
    );

    my $res = $self->ua->get($uri);
    croak $res->status_line if $res->is_error;

    WebService::KakakuCom::Parser->parse_for_product($res->content);
}

1;

__END__