File Coverage

blib/lib/WebService/Geocodio.pm

Criterion	Covered	Total	%
statement	18	48	37.5
branch	0	16	0.0
condition			n/a
subroutine	6	13	46.1
pod	6	6	100.0
total	30	83	36.1

use 5.014;

use strict;
use warnings;

package WebService::Geocodio;
{
  $WebService::Geocodio::VERSION = '0.04';
}

use Moo::Lax;
use Carp qw(confess);
use Scalar::Util qw(blessed);
with('WebService::Geocodio::Request');

# ABSTRACT: A Perl interface to Geocod.io



has 'api_key' => (
    is => 'ro',
    isa => sub { confess "$_[0] doesn't look like a valid api key\n" unless $_[0] =~ /[0-9a-f]+/ },
    required => 1,
);


has 'locations' => (
    is => 'rw',
    default => sub { [] },
);


has 'fields' => (
    is => 'rw',
    predicate => 1,
    default => sub { [] },
);


sub add_location {
    my $self = shift;

    push @{ $self->locations }, @_;
}


sub show_locations {
    my $self = shift;

    return @{ $self->locations };
}


sub clear_locations {
    my $self = shift;

    $self->locations([]);
}


sub add_field {
    my $self = shift;

    push @{ $self->fields }, grep { /cd|cd113|stateleg|timezone|school/ } @_;
}


sub geocode {
    my $self = shift;

    $self->add_location(@_) if scalar @_;

    return undef if scalar @{$self->locations} < 1;

    my @r = $self->send_forward( $self->_format('forward') );

    wantarray ? return @r : return \@r;
}


sub reverse_geocode {
    my $self = shift;

    $self->add_location(@_) if scalar @_;

    return undef if scalar @{$self->locations} < 1;

    my @r = $self->send_reverse( $self->_format('reverse') );

    wantarray ? return @r : return \@r;
}

sub _format {
    my $self = shift;
    my $direction = shift;

    my $method = $direction eq 'forward' ? '_forward_formatting'
        : '_reverse_formatting';

    return [ map {; blessed $_ ? $_->$method : $_ } @{$self->locations} ];
}

1;

__END__