File Coverage

blib/lib/Web/MarketReceipt/Verifier/Mock/AppStore.pm

Criterion	Covered	Total	%
statement	38	38	100.0
branch	1	2	50.0
condition			n/a
subroutine	9	9	100.0
pod	0	1	0.0
total	48	50	96.0

package Web::MarketReceipt::Verifier::Mock::AppStore;
use Mouse;
use utf8;

extends 'Web::MarketReceipt::Verifier';

use Web::MarketReceipt;
use MIME::Base64 qw/decode_base64/;

has verifier => (
    is      => 'ro',
    isa     => 'CodeRef',
    default => sub {
        my $self = shift;

        return sub { $self->_default_verifier(@_) };
    },
    lazy    => 1,
);

no Mouse;

sub _default_verifier {
    my ($self, %args) = @_;

    my $receipt = $args{receipt};

    my $parsed = $self->_parse_receipt($receipt);

    my $purchase_info = $parsed->{'purchase-info'};
    my %underscored = (
        map {
            my $key = $_;
            $key =~ s/-/_/g;
            $key => $purchase_info->{$_}
        } keys %$purchase_info
    );
    my $environment = exists $parsed->{environment} ?
        $parsed->{environment} : 'Production';

    my $result = Web::MarketReceipt->new(
        is_success => 1,
        store      => 'AppStore',
        raw        => \%underscored,
        orders     => [
            {
                product_identifier => $underscored{product_id},
                unique_identifier  => 'AppStore:' . $underscored{original_transaction_id},
                purchased_epoch    => $underscored{original_purchase_date_ms},
                quantity           => $underscored{quantity},
                environment        => $environment,
                state              => 'purchased',
            }
        ],
    );

    return $result;
}

sub verify {
    my $self = shift;

    return $self->verifier->(@_);
}

sub _parse_receipt {
    my ($class, $receipt) = @_;

    my $data = $class->_parse_oldstlye_plist($receipt);
    my $purchase_info = $class->_parse_oldstlye_plist($data->{'purchase-info'});
    $data->{'purchase-info'} = $purchase_info;

    return $data;
}

# XXX: This parser is poor but I look work with a receipt from appstore.
# If that do not parse at your receipt, please report issues or pull requests.
sub _parse_oldstlye_plist {
    my ($class, $text) = @_;

    my $data = decode_base64($text);
    my ($properties_str) = $data =~ /{(.*)}/s;
    my %kv = $properties_str =~ /\s*"(.*?)"\s*=\s*"(.*?)"\s*;/msg;

    return \%kv;
}

1;

__END__