File Coverage

lib/Web/Components/Role/TT.pm

Criterion	Covered	Total	%
statement	42	42	100.0
branch	10	12	100.0
condition	4	8	50.0
subroutine	11	11	100.0
pod	1	1	100.0
total	68	74	94.5

package Web::Components::Role::TT;

use 5.010001;
use namespace::autoclean;
use version; our $VERSION = qv( sprintf '0.8.%d', q$Rev: 1 $ =~ /\d+/gmx );

use File::DataClass::Constants qw( EXCEPTION_CLASS NUL TRUE );
use File::DataClass::Types     qw( Directory Object );
use Template;
use Unexpected::Functions      qw( PathNotFound throw );
use Moo::Role;

requires qw( config ); # layout skin tempdir vardir

# Attribute constructors
my $_build_templates = sub {
   my $self = shift; my $conf = $self->config; my $dir;

   $conf->can( 'vardir' ) and $dir = $conf->vardir->catdir( 'templates' );

   return ($dir && $dir->exists) ? $dir : $conf->root->catdir( 'templates' );
};

my $_build__templater = sub {
   my $self        =  shift;
   my $args        =  {
      COMPILE_DIR  => $self->config->tempdir->catdir( 'ttc' ),
      COMPILE_EXT  => 'c',
      ENCODING     => 'utf8',
      RELATIVE     => TRUE,
      INCLUDE_PATH => [ $self->templates->pathname ], };
   # uncoverable branch true
   my $template    =  Template->new( $args ) or throw $Template::ERROR;

   return $template;
};

# Public attributes
has 'templates'  => is => 'lazy', isa => Directory, coerce => TRUE,
   builder       => $_build_templates;

# Private attributes
has '_templater' => is => 'lazy', isa => Object, builder => $_build__templater;

# Private functions
my $_layout = sub {
   my ($conf, $stash) = @_;

   my $page   = $stash->{page} //= {};
   my $plate  = $stash->{template} //= {};
   my $layout = $plate->{layout} // $page->{layout} // $conf->layout;

   return $plate->{layout} = $page->{layout} = $layout;
};

my $_skin = sub {
   my ($conf, $stash) = @_;

   my $plate = $stash->{template} //= {};
   my $skin  = $plate->{skin} // $stash->{skin} // $conf->skin;

   return $plate->{skin} = $stash->{skin} = $skin;
};

my $_rel_template_path = sub {
   my ($self, $conf, $stash, $layout) = @_; my $templates = $self->templates;

   my $path = $templates->catfile( $_skin->( $conf, $stash ), "${layout}.tt" );

   $path->exists and return $path->abs2rel( $templates );

   my $alt  = $templates->catfile( $conf->skin, "${layout}.tt" );

   $alt->exists or throw PathNotFound, [ $path ];

   return $alt->abs2rel( $templates );
};

# Public methods
sub render_template {
   my ($self, $stash) = @_; $stash //= {};

   my $result = NUL;
   my $conf   = $stash->{config} //= $self->config;
   my $layout = $_layout->( $conf, $stash );

   if (ref $layout) {
      $self->_templater->process( $layout, $stash, \$result )
         or throw $self->_templater->error;
   }
   else {
      my $path = $self->$_rel_template_path( $conf, $stash, $layout );

      # uncoverable branch true
      $self->_templater->process( $path, $stash, \$result )
         or throw $self->_templater->error;
   }

   return $result;
}

1;

__END__