File Coverage

blib/lib/Wasm/Hook.pm

Criterion	Covered	Total	%
statement	47	48	97.9
branch	8	10	80.0
condition			n/a
subroutine	11	11	100.0
pod			n/a
total	66	69	95.6

package Wasm::Hook;

use strict;
use warnings;
use autodie;
use 5.008001;
use Wasm 0.02;
use Ref::Util qw( is_ref );
use Path::Tiny qw( path );
use Scalar::Util qw( refaddr );

# ABSTRACT: Automatically load WebAssembly modules without a Perl wrapper
our $VERSION = '0.02'; # VERSION


sub _hook
{
  my(undef, $file) = @_;
  foreach my $inc (@INC)
  {
    next if ref $inc;
    my $pm = path($inc)->child($file);
    return () if -f $pm;
    my $basename = $pm->basename;
    $basename =~ s/\.pm$//;
    my($wa) = sort { $b->stat->mtime <=> $a->stat->mtime }
              grep { -f $_ }
              map { $pm->parent->child($basename . $_) }
              qw( .wasm .wat );
    next unless defined $wa;
    if(-f $wa)
    {
      my $package = $file;
      $package =~ s/\.pm$//;
      $package =~ s/\//::/g;
      my $perl = qq{package $package; use Wasm -api => 0, -exporter => 'ok', -file => "$wa"; 1;\n};
      my $fh;
      open $fh, '<', \$perl;
      return ($fh);
    }
  }
  return ();
}

sub import
{
  __PACKAGE__->unimport;
  push @INC, \&_hook;
}

sub unimport
{
  @INC = grep { !is_ref($_) || refaddr($_) != refaddr(\&_hook) } @INC;
}

1;

__END__