File Coverage

blib/lib/Wasm/Wasmtime/Module.pm

Criterion	Covered	Total	%
statement	70	70	100.0
branch	11	12	91.6
condition			n/a
subroutine	18	18	100.0
pod	4	4	100.0
total	103	104	99.0

package Wasm::Wasmtime::Module;

use strict;
use warnings;
use 5.008004;
use Ref::Util qw( is_blessed_ref );
use Wasm::Wasmtime::FFI;
use Wasm::Wasmtime::Engine;
use Wasm::Wasmtime::Store;
use Wasm::Wasmtime::Module::Exports;
use Wasm::Wasmtime::Module::Imports;
use Wasm::Wasmtime::ImportType;
use Wasm::Wasmtime::ExportType;
use Ref::Util qw( is_blessed_ref );
use Carp ();

# ABSTRACT: Wasmtime module class
our $VERSION = '0.22'; # VERSION


$ffi_prefix = 'wasm_module_';
$ffi->load_custom_type('::PtrObject' => 'wasm_module_t' => __PACKAGE__);

sub _args
{
  my $wasm;
  my $data;
  if(@_ == 1)
  {
    $data = shift;
    $wasm = Wasm::Wasmtime::ByteVec->new($data);
  }
  else
  {
    my $key = shift;
    if($key eq 'wat')
    {
      require Wasm::Wasmtime::Wat2Wasm;
      $data = Wasm::Wasmtime::Wat2Wasm::wat2wasm(shift);
      $wasm = Wasm::Wasmtime::ByteVec->new($data);
    }
    elsif($key eq 'wasm')
    {
      $data = shift;
      $wasm = Wasm::Wasmtime::ByteVec->new($data);
    }
    elsif($key eq 'file')
    {
      require Wasm::Wasmtime::Wat2Wasm;
      require Path::Tiny;
      my $path = Path::Tiny->new(shift);
      if($path->basename =~ /\.wat/)
      {
        $data = Wasm::Wasmtime::Wat2Wasm::wat2wasm($path->slurp_utf8);
        $wasm = Wasm::Wasmtime::ByteVec->new($data);
      }
      else
      {
        $data = $path->slurp_raw;
        $wasm = Wasm::Wasmtime::ByteVec->new($data);
      }
    }
  }
  (\$wasm, \$data);
}


$ffi->attach( [ wasmtime_module_new => 'new' ] => ['wasm_engine_t', 'wasm_byte_vec_t*', 'opaque*'] => 'wasmtime_error_t' => sub {
  my $xsub = shift;
  my $class = shift;
  my $store;
  my $engine;
  if(defined $_[0] && is_blessed_ref $_[0])
  {
    if($_[0]->isa('Wasm::Wasmtime::Engine'))
    {
      $engine = shift;
    }
    elsif($_[0]->isa('Wasm::Wasmtime::Store'))
    {
      Carp::carp("Passing a Wasm::Wasmtime::Store into the module constructor is deprecated, please pass a Wasm::Wasmtime::Engine object instead");
      $store = shift;
      $engine = $store->engine;
    }
  }
  $engine ||= Wasm::Wasmtime::Engine->new;
  my($wasm, $data) = _args(@_);
  my $ptr;
  if(my $error = $xsub->($engine, $$wasm, \$ptr))
  {
    Carp::croak("error creating module: " . $error->message);
  }
  bless { ptr => $ptr, engine => $engine, store => $store }, $class;
});


$ffi->attach( [ wasmtime_module_deserialize => 'deserialize' ] => ['wasm_engine_t', 'wasm_byte_vec_t*', 'opaque*'] => 'wasmtime_error_t' => sub {
  my $xsub  = shift;
  my $class = shift;
  my $engine;
  $engine = defined $_[0] && is_blessed_ref $_[0] && $_[0]->isa('Wasm::Wasmtime::Engine') ? shift : Wasm::Wasmtime::Engine->new;
  my $serialized = Wasm::Wasmtime::ByteVec->new($_[0]);
  my $ptr;
  if(my $error = $xsub->($engine, $serialized, \$ptr))
  {
    Carp::croak("error creating module: " . $error->message);
  }
  bless { ptr => $ptr, store => undef, engine => $engine }, $class;
});


$ffi->attach( [ wasmtime_module_validate => 'validate' ] => ['wasm_store_t', 'wasm_byte_vec_t*'] => 'wasmtime_error_t' => sub {
  my $xsub = shift;
  my $class = shift;
  my $store = defined $_[0] && ref($_[0]) eq 'Wasm::Wasmtime::Store' ? shift : Wasm::Wasmtime::Store->new;
  my($wasm, $data) = _args(@_);
  my $error = $xsub->($store, $$wasm);
  wantarray  ## no critic (Community::Wantarray)
    ? $error ? (0, $error->message) : (1, '')
    : $error ? 0 : 1;
});


sub exports
{
  Wasm::Wasmtime::Module::Exports->new(shift);
}

$ffi->attach( [ exports => '_exports' ]=> [ 'wasm_module_t', 'wasm_exporttype_vec_t*' ] => sub {
  my($xsub, $self) = @_;
  my $exports = Wasm::Wasmtime::ExportTypeVec->new;
  $xsub->($self, $exports);
  $exports->to_list;
});


sub imports
{
  Wasm::Wasmtime::Module::Imports->new(shift);
}

$ffi->attach( [ imports => '_imports' ] => [ 'wasm_module_t', 'wasm_importtype_vec_t*' ] => sub {
  my($xsub, $self) = @_;
  my $imports = Wasm::Wasmtime::ImportTypeVec->new;
  $xsub->($self, $imports);
  $imports->to_list;
});


$ffi->attach( [ 'wasmtime_module_serialize' => 'serialize' ] => [ 'wasm_module_t', 'wasm_byte_vec_t*' ] => 'wasmtime_error_t' => sub {
  my($xsub, $self) = @_;
  my $s = Wasm::Wasmtime::ByteVec->new;
  if(my $error = $xsub->($self, $s))
  {
    Carp::croak("error serializing module: " . $error->message);
  }
  else
  {
    my $s2 = $s->get;
    $s->delete;
    return $s2;
  }
});


sub engine { shift->{engine} }


sub to_string
{
  my($self) = @_;
  my @externs = (@{ $self->imports }, @{ $self->exports });
  return "(module)\n" unless @externs;
  my $string = "(module\n";
  foreach my $extern (@externs)
  {
    $string .= "  " . $extern->to_string . "\n";
  }
  $string .= ")\n";
}

_generate_destroy();

1;

__END__