File Coverage

blib/lib/WWW/Slides/Controller/Single.pm

Criterion	Covered	Total	%
statement	51	51	100.0
branch	14	22	63.6
condition	1	3	33.3
subroutine	13	13	100.0
pod	6	7	85.7
total	85	96	88.5

package WWW::Slides::Controller::Single;
{

   use version; our $VERSION = qv('0.0.9');

   use warnings;
   use strict;
   use Carp;
   use English qw( -no_match_vars );

   use Object::InsideOut qw( WWW::Slides::Controller );

   # Module implementation here
   my @in_handle : Field    # controller handle
     : Std(Name => 'in_handle', Private => 1)
     : Arg(Name => 'in_handle', Mandatory => 1);
   my @out_handle : Field : Std(Name => 'out_handle', Private => 1)
     : Arg(Name => 'out_handle');

   sub is_alive {
      my $self = shift;
      return defined($self->get_in_handle());
   }

   sub shut_down {
      my $self = shift;
      $self->release_selector() if $self->selector();
      $self->get_in_handle()->close() if $self->get_in_handle();
      $self->set_in_handle(undef);
      $self->get_out_handle()->close() if $self->get_out_handle();
      $self->set_out_handle(undef);
      return;
   }

   sub set_selector {
      my ($self, $selector) = @_;
      $selector->add($self->get_in_handle()) if $self->is_alive();
      $self->SUPER::set_selector($selector);
      return;
   }

   sub release_selector {
      my $self = shift;
      return unless $self->is_alive();
      $self->selector()->remove($self->get_in_handle());
      return;
   }

   sub owns {
      my $self = shift;
      my ($fh) = @_;
      return unless $self->is_alive();
      return unless defined $fh;
      return $self->get_in_handle() == $fh;
   } ## end sub owns

   sub output {
      my $self = shift;
      croak 'object is not alive, no output possible'
         unless $self->is_alive();
      my $fh = $self->get_out_handle() or return;
      print {$fh} @_;
      return;
   }

   sub get_input_chunk {
      my $self = shift;
      croak 'not alive, cannot input' unless $self->is_alive();
      $self->get_in_handle()->sysread(my $newstuff, 4096);
      return unless defined $newstuff and length $newstuff;
      return $newstuff;
   }
}

1;    # Magic true value required at end of module
__END__