File Coverage

blib/lib/WWW/Shorten/IsGd.pm

Criterion	Covered	Total	%
statement	15	32	46.8
branch	0	18	0.0
condition			n/a
subroutine	5	7	71.4
pod	2	2	100.0
total	22	59	37.2

package WWW::Shorten::IsGd;

use strict;
use warnings;

use base qw( WWW::Shorten::generic Exporter );
our @EXPORT = qw( makeashorterlink makealongerlink );

use Carp ();
use HTML::Entities qw(decode_entities);

our $VERSION = '0.005';
$VERSION = eval $VERSION;

sub makeashorterlink {
    my $url = shift or Carp::croak('No URL passed to makeashorterlink');
    my $ua = __PACKAGE__->ua();
    my $response = $ua->post('https://is.gd/create.php', {
        url => $url,
        format => 'simple',
    });

    return undef unless $response->is_success;
    my $shorturl = $response->decoded_content;
    return undef unless $shorturl;
    return undef if $shorturl =~ m/^\s*Error/;
    return $shorturl;
}

sub makealongerlink {
    my $url = shift or Carp::croak('No is.gd key/URL passed to makealongerlink');
    my $ua = __PACKAGE__->ua();

    $url = "https://is.gd/$url" unless $url =~ m{^https?://}i;
    my $res = $ua->post('https://is.gd/forward.php', {
        shorturl => $url,
        format => 'simple',
    });

    return undef unless $res->is_success;
    my $longurl = $res->decoded_content;
    return undef unless $longurl;
    return undef if $longurl =~ m/^\s*Error/;
    return decode_entities($longurl);
}

1;

__END__