File Coverage

blib/lib/WWW/Pastebin/Base/Retrieve.pm

Criterion	Covered	Total	%
statement	30	52	57.6
branch	1	10	10.0
condition	2	8	25.0
subroutine	8	14	57.1
pod	0	2	0.0
total	41	86	47.6

package WWW::Pastebin::Base::Retrieve;

use warnings;
use strict;

our $VERSION = '0.002';

use Carp;
use URI;
use LWP::UserAgent;
use base 'Class::Data::Accessor';

__PACKAGE__->mk_classaccessors( qw(
    ua
    uri
    id
    content
    error
    results
));

use overload q|""| => sub { shift->content };

sub new {
    my $class = shift;
    croak "Must have even number of arguments to new()"
        if @_ & 1;

    my %args = @_;
    $args{ +lc } = delete $args{ $_ } for keys %args;

    $args{timeout} ||= 30;
    $args{ua} ||= LWP::UserAgent->new(
        timeout => $args{timeout},
        agent   => 'Mozilla/5.0 (X11; U; Linux x86_64; en-US; rv:1.8.1.12)'
                    .' Gecko/20080207 Ubuntu/7.10 (gutsy) Firefox/2.0.0.12',
    );

    my $self = bless {}, $class;
    $self->ua( $args{ua} );

    return $self;
}

sub retrieve {
    my $self = shift;
    my $id   = shift;

    $self->$_(undef) for qw(error uri id results);

    return $self->_set_error('Missing or empty paste ID or URI')
        unless defined $id and length $id;

    ( my $uri, $id ) = $self->_make_uri_and_id( $id, @_ )
        or return;

    $self->id( $id );
    $self->uri( $uri );

    my $ua = $self->ua;
    my $response = $ua->get( $uri );
    if ( $response->is_success ) {
        return $self->_get_was_successful( $response->content );
    }
    else {
        return $self->_set_error('Network error: ' . $response->status_line);
    }
}

sub _get_was_successful {
    my ( $self, $content ) = @_;
    return $self->results( $self->_parse( $content ) );
}

sub _set_error {
    my ( $self, $error_or_response_obj, $is_net_error ) = @_;
    if ( defined $is_net_error ) {
        $self->error( 'Network error: ' . $error_or_response_obj->status_line
        );
    }
    else {
        $self->error( $error_or_response_obj );
    }
    return;
}

sub _parse {
    croak "Looks like the author of the module forgot to override the"
            . "_parse() methods";
}

sub _make_uri_and_id {
    croak "Looks like the author of the module forgot to override the"
            . "_make_uri_and_id() methods";
}

1;
__END__