File Coverage

blib/lib/WWW/ImagebinCa/Retrieve.pm

Criterion	Covered	Total	%
statement	49	91	53.8
branch	7	36	19.4
condition	2	20	10.0
subroutine	9	10	90.0
pod	2	2	100.0
total	69	159	43.4

package WWW::ImagebinCa::Retrieve;

use warnings;
use strict;

our $VERSION = '0.01';

use Carp;
use URI;
use LWP::UserAgent;
require File::Spec;
use HTML::TokeParser::Simple;
use base qw(Class::Data::Accessor);

__PACKAGE__->mk_classaccessors( qw(
        page_id  image_uri  page_uri  description  error
        full_info  what  where  do_download_image
    )
);

sub new {
    my $class = shift;
    croak "Must have even number of arguments to new()"
        if @_ & 1;
    my %args = @_;
    $args{ +lc } = delete $args{ $_ } for keys %args;

    $args{timeout} ||= 30;

    $args{ua} ||= LWP::UserAgent->new(
            timeout => $args{timeout},
            agent   => 'Mozilla/5.0 (X11; U; Linux x86_64; en-US;'
                        . ' rv:1.8.1.12) Gecko/20080207 Ubuntu/7.10 (gutsy)'
                        . ' Firefox/2.0.0.12',
    );

    return bless \%args, $class;
}

sub retrieve {
    my $self = shift;
    my %args;
    if ( @_ == 1 ) {
        $args{what} = shift;
    }
    else {
        croak "Must have even number or only 1 argument to retrieve()"
            if @_ & 1;
        %args = @_;
        $args{ +lc } = delete $args{ $_ } for keys %args;
    }
    for (qw(page_id image_uri where page_uri description error full_info)){
        $self->$_( undef );
    }

    unless ( defined $args{do_download_image} ) {
        $args{do_download_image} = 1;
    }

    unless ( defined $args{what} ) {
        $self->error('Undefined page ID was specified');
        return;
    }

    $self->what( $args{what} );
    $args{what} =~ s{http://imagebin.ca/view/(\S+?).html}{$1}i;
    $self->page_id( $args{what} );

    $self->do_download_image( $args{do_download_image} );

    my $page_uri = URI->new("http://imagebin.ca/view/$args{what}.html");
    my $response = $self->{ua}->get($page_uri);
    if ( $response->is_success ) {
        $self->page_uri($page_uri);

        my $full_info_ref
        = $self->_parse_response( $response->content, \%args );

        return $self->full_info( $full_info_ref );
    }
    else {
        $self->error($response->status_line);
        return;
    }
}

sub _parse_response {
    my ( $self, $content, $args_ref ) = @_;

    my $parser = HTML::TokeParser::Simple->new( \$content );

    my ( $description, $image_uri );
    my $get_description = 0;
    while ( my $token = $parser->get_token ) {
        if ( $token->is_start_tag('img')
            and $token->get_attr('id')
            and $token->get_attr('id') eq 'theimg'
        ) {
            $image_uri = URI->new($token->get_attr('src'));
            $get_description = 1;
        }
        elsif ( $get_description == 1
            and $token->is_start_tag('div')
            and defined $token->get_attr('style')
        ) {
            if ( $token->get_attr('style') =~ /background/i ) {
                $get_description = 2;
            }
            else {
                last;
            }
        }
        elsif ( $get_description == 2 and $token->is_text ) {
            $description = $token->as_is;
            last;
        }
    }
    unless ( defined $image_uri ) {
        $self->error(q|This page ID doesn't seem to exist|);
        return;
    }

    unless ( defined $description ) {
        $description = 'N/A';
    }

    $self->image_uri($image_uri);
    $self->description($description);

    if ( $args_ref->{do_download_image} ) {
        my $image_uri_filename = ($image_uri->path_segments)[-1];
        my ( $extension ) = $image_uri_filename =~ /([.][^.]+$)/;

        my $save_as_where_file;
        if ( defined $args_ref->{save_as} ) {
            $save_as_where_file = File::Spec->catfile(
                $args_ref->{where},
                $args_ref->{save_as} . $extension
            );
        }

        my $where_file = File::Spec->catfile(
            $args_ref->{where},
            $image_uri_filename,
        );

        my $local_name ;
        if ( defined $args_ref->{save_as} ) {
            $local_name = defined $args_ref->{where}
                        ? $save_as_where_file
                        : $args_ref->{save_as} . $extension;
        }
        else {
            $local_name = defined $args_ref->{where}
                        ? $where_file
                        : $image_uri_filename;
        }

        my $response = $self->{ua}->mirror( $image_uri, $local_name );
        if ( $response->is_success ) {
            $args_ref->{where} = $local_name;
        }
        else {
            $self->error(
                'Failed to download image: ' . $response->status_line
            );
            return;
        }
    }
    return $self->full_info( {
            page_id     => $self->page_id,
            page_uri    => $self->page_uri,
            image_uri   => $image_uri,
            description => $description,
            where       => $self->where( $args_ref->{where} ),
            what        => $self->what,
        }
    );
}


1;

__END__