File Coverage

blib/lib/WWW/FCM/HTTP.pm

Criterion	Covered	Total	%
statement	47	47	100.0
branch	7	8	87.5
condition	10	12	83.3
subroutine	13	13	100.0
pod	2	3	66.6
total	79	83	95.1

package WWW::FCM::HTTP;
use 5.008001;
use strict;
use warnings;

our $VERSION = "0.03";

use LWP::UserAgent;
use LWP::Protocol::https;
use LWP::ConnCache;
use JSON qw(encode_json);
use Class::Accessor::Lite (
    new => 0,
    rw  => [qw/ua api_url api_key json/],
);
use Carp qw(croak);

use WWW::FCM::HTTP::Response;

our $API_URL = 'https://fcm.googleapis.com/fcm/send';

sub new {
    my $class = shift;
    my %args  = $_[0] && ref $_[0] eq 'HASH' ? %{ $_[0] } : @_;
    croak 'Usage: WWW::FCM::HTTP->new({ api_key => $api_key })'
        unless (exists $args{api_key} && defined $args{api_key});

    $args{api_url} ||= $API_URL;
    $args{ua}      ||= LWP::UserAgent->new(
        agent      => __PACKAGE__.'/'.$VERSION,
        conn_cache => LWP::ConnCache->new,
    );

    bless { %args }, $class;
}

sub send {
    my ($self, $payload) = @_;
    croak 'Usage: $fcm->send(\%payload)' unless ref $payload eq 'HASH';

    my $res = $self->ua->request($self->build_request($payload));
    WWW::FCM::HTTP::Response->new($res, $payload->{registration_ids});
}

sub build_request {
    my ($self, $payload) = @_;
    croak 'Usage: $gcm->build_request(\%payload)' unless ref $payload eq 'HASH';

    my $req = HTTP::Request->new(POST => $self->api_url);
    $req->header(Authorization => 'key='.$self->api_key);
    $req->header('Content-Type' => 'application/json; charset=UTF-8');
    $req->content(encode_json $payload);

    return $req;
}

1;
__END__