File Coverage

blib/lib/WWW/ErnestMarples.pm

Criterion	Covered	Total	%
statement	34	38	89.4
branch	5	12	41.6
condition	1	9	11.1
subroutine	9	9	100.0
pod	2	2	100.0
total	51	70	72.8

package WWW::ErnestMarples;

use warnings;
use strict;

use Carp;
use HTML::Tiny;
use LWP::UserAgent;

=head1 NAME

WWW::ErnestMarples - Interface to the ernestmarples.com UK postcode lookup API

=head1 VERSION

This document describes WWW::ErnestMarples version 0.01

=cut

our $VERSION = '0.01';

use constant SERVICE => 'http://ernestmarples.com/';

=head1 SYNOPSIS

  use WWW::ErnestMarples;

  my $em = WWW::ErnestMarples->new;
  my ( $lat, $lon ) = $em->lookup('CA9 3NT');

=head1 INTERFACE

=head2 C<< new >>

Create a new C. Accepts named arguments. The only
argument currently supported is C which gives the base URL of
the lookup service. Defaults to C.

  my $em = WWW::ErnestMarples->new(
    service => 'http://localhost/emtest.cgi'
  );

For normal use pass no args:

  my $em = WWW::ErnestMarples->new;

=cut

sub new {
  my $class = shift;
  croak "Expected a number of key => value pairs" if @_ % 1;
  my %args    = @_;
  my $service = delete $args{service};
  $service = $class->SERVICE unless defined $service;
  croak "Unknown options: ", join ', ', sort keys %args if keys %args;
  return bless { service => $service }, $class;
}

=head2 C

Look up a UK postcode. The return value is a list containing latitude,
longitude of the postcode.

  my ( $lat, $lon ) = $em->lookup( $my_postcode );

=cut

sub lookup {
  my ( $self, $postcode ) = @_;

  my $resp
   = $self->_ua->get( $self->{service} . '?'
     . HTML::Tiny->new->query_encode( { p => $postcode, f => 'csv' } )
   );

  croak $resp->status_line if $resp->is_error;
  croak "Bad response from $self->{service}; is that a valid postcode?"
   unless $resp->content_type =~ m{^text/csv\b};
  chomp( my $content = $resp->content );
  my ( $pc, $lat, $lon ) = split /,/, $content;
  croak "Bad response from $self->{service}; could not parse response"
   unless defined $lon
     && $lat =~ /^-?\d+(?:\.\d+)?$/
     && $lon =~ /^-?\d+(?:\.\d+)?$/;
  return $lat, $lon;
}

sub _ua {
  my $self = shift;
  return $self->{_ua} ||= do {
    my $ua = LWP::UserAgent->new;
    $ua->agent( sprintf( '%s %s', __PACKAGE__, $VERSION ) );
    $ua;
  };
}

1;
__END__